Add value to dictionary key only if it is not already present - dictionary

Question

I find that I am often wanting to append values to dictionary lists, but only if the value is not in the list already. Therefore, I'm trying to separate this out into a procedure, and I can't figure out why the following code doesn't achieve this:
proc DictAdd {_dictionary key value} {
upvar 1 $_dictionary dictionary
if { $value ni [dict get $dictionary $key] } {
dict lappend dictionary $key $value
}
}
Calling this procedure returns the following error:
can't read "dictionary": no such variable
while executing
"dict get $dictionary $key"
(procedure "DictAdd" line 5)
invoked from within
"DictAdd $files baseline $fileName"
(procedure "getFilesToLoad" line 53)
invoked from within
...
Could someone please tell me what I'm doing wrong here? Thanks.

Answer 1

In the invocation
DictAdd $files baseline $fileName
$files is the value of your dictionary, but DictAdd expects the name of the dictionary variable. If you instead invoke it like this:
DictAdd files baseline $fileName
the command works as designed.
BTW: if you define DictAdd like this:
proc DictAdd {_dictionary key value} {
upvar 1 $_dictionary dictionary
if {[dict exists $dictionary $key]} {
dict with dictionary {
upvar 0 $key values
if {$value ni $values} {
lappend values $value
}
}
} else {
dict lappend dictionary $key $value
}
}
you don't get an error message if the key is missing (it adds the value under that key) (the dictionary still needs to exist outside DictAdd) and the checking/adding code gets a little less messy.
Why the name? It’s because of how upvar works. The command takes a stack level (in this case 1 = the caller’s level) and a variable name (contained in _dictionary; “files” in this case); using those it locates a variable outside the executing command, and creates a local alias inside the executing command (in this case named dictionary: files outside is now basically the same variable as dictionary inside). If you pass something else, e.g. the value of files, say {baseline {a b c}}, upvar will look for a variable called {baseline {a b c}} and most likely not find it. It will create the alias anyway, and if you initialize it, a variable called {baseline {a b c}} at the caller’s level will actually be created. But, again, you will want to use the name of the variable (of course, the name of the variable could be the value of another variable when you invoke the command…).
Documentation: dict, if, lappend, ni operator, proc, upvar

Answer 2

The problem is most likely that the dictionary variable that you are referring to is actually unset, and so impossible to read. Try this:
proc DictAdd {_dictionary key value} {
upvar 1 $_dictionary dictionary
if {![info exists dictionary]} {
set dictionary [dict create $key [list $value]]
} elseif {$value ni [dict get $dictionary $key]} {
dict lappend dictionary $key $value
}
}