List(Of <custom class>) Seems to Reset Itself - asp.net

Question

Code:
I have a class, Pricing.vb, that accepts an IEnumerable(Of tblAccount) in its new method, where tblAccount is an Entity Framework class with an added partial class that adds non-mapped properties.
Pricing.vb:
Public Property accounts As IEnumerable(Of tblAccount)
Public Sub New(ByVal accts As IEnumerable(Of tblAccount))
Me.accounts = accts
End Sub
tblAccount.vb:
Partial Public Class tblAccount
<NotMapped>
Public Property irr As Double
End Class
The Pricing.vb class then has a method, CalcBalance:
Public Sub CalcBalance(reqPrice As Double)
Dim acctsByIRR As List(Of Long)
Dim i As Long = 0
Me.FillCashFlows(reqPrice)
Me.FillMetrics()
acctsByIRR = Me.accounts.OrderBy(Function(t) t.irr).Select(Function(t) t.acct_id).ToList()
'do ... while that removes accounts 1 by 1 by lowest ray until it is above min
Do While Me.netIRR < Me.minimumIRR
Me.accounts = Me.accounts.Where(Function(t) t.acct_id <> acctsByIRR(i))
i = i + 1
If Me.accounts.Count = 0 Then Exit Sub
Me.FillCashFlows(reqPrice)
Me.FillMetrics()
Loop
End Sub
Basically, the CalcBalance() method is designed to remove tblAccount objects one-by-one from its property Me.Accounts, in order of lowest IRR, until the IRR of the remaining accounts (Me.netIRR) meets a minimum criteria (Me.minimumIRR). The Me.netIRR property is calculated by methods FillCashFlows() and FillMetrics().
Problem:
The problem that I'm seeing, though, is that Me.accounts essentially resets itself each time the do while...loop loops. So if I have tblAccounts with acct_ids 1 through 5, and let's say that the order of lowest IRRs is 1, 2, 3, 4, and 5, then the first time the method loops it will properly remove acct_id=1 from Me.accounts. BUT, the next time it loops, acct_id=1 will reappear in Me.accounts, and it will remove acct_id=2. It will continue this weird process until of course it hits an index out of range exception.
For a little visualization, here's what the IEnumerable(Of tblAccount) looks like, by acct_id after each loop:
After 1st loop:
2
3
4
5
After 2nd loop:
1
3
4
5
After 3rd loop:
1
2
4
5
After 4th loop:
1
2
3
5
After 5th loop:
1
2
3
4
It should look like this:
After 1st loop:
2
3
4
5
After 2nd loop:
3
4
5
After 3rd loop:
4
5
After 4th loop:
5
After 5th loop:
empty, and Exit Sub

Answer 1

It's because you're using IEnumerable<T> and not List<T>. LINQ query is lazy loaded, so your accounts property stores the query information (how to get the results) not a list of accounts. In every iteration of Do/While you just change the definition, and later on it's called against initial data source over and over again.
Make sure to call ToList whenever you assign to accounts:
Public Sub New(ByVal accts As IEnumerable(Of tblAccount))
Me.accounts = accts.ToList()
End Sub
and
Public Sub CalcBalance(reqPrice As Double)
Dim acctsByIRR As List(Of Long)
Dim i As Long = 0
Me.FillCashFlows(reqPrice)
Me.FillMetrics()
acctsByIRR = Me.accounts.OrderBy(Function(t) t.irr).Select(Function(t) t.acct_id).ToList()
'do ... while that removes accounts 1 by 1 by lowest ray until it is above min
Do While Me.netIRR < Me.minimumIRR
Me.accounts = Me.accounts.Where(Function(t) t.acct_id <> acctsByIRR(i)).ToList()
i = i + 1
If Me.accounts.Count = 0 Then Exit Sub
Me.FillCashFlows(reqPrice)
Me.FillMetrics()
Loop
End Sub