Julia: how to remove rows by condition with a search across the entire dataframe - julia

Question

Sometimes there is a need to delete rows by some condition in a large dataframe, where it is irrational to manually specify all columns by name. For example, such a situation may occur if the value "no data" is set as some specific numeric value, for example "-1". It would be useful to be able to immediately delete all the rows where this value occurs, similar to how dropmissing() removes them. I have not found a convenient way to replace an arbitrary value with "missing" or directly delete all lines where the specified value occurs.
Simple example:
df = DataFrame(A=[2, -1, 3, 3], B=[2, 5, 7, -1], C=3)
I want to delete all rows where -1 values occur, or at least extract all rows where this value does not occur. Something like this:
df_clear = df[df .>= 0, :]
or:
df_clear = df[findall(x -> x>0, df), :]
A similar syntax works with replacing values, but it doesn't seem to be applicable for deleting strings:
df .= ifelse.(df.< 0, 0, df)
What is the most elegant way to solve this problem? Is there a beautiful solution to perform such a check on a range of columns or on all columns except for the specified one?

Answer 1

You could do it e.g. like this (using the ifelse function you used; the approach assumes you do not have missing values in your data frame):
julia> dropmissing!(ifelse.(df .== -1, missing, df))
2×3 DataFrame
Row │ A B C
│ Int64 Int64 Int64
─────┼─────────────────────
1 │ 2 2 3
2 │ 3 7 3
A more direct approach is to use the subset function by keeping rows in which -1 is not present:
julia> subset(df, All() .=> ByRow(!=(-1)))
2×3 DataFrame
Row │ A B C
│ Int64 Int64 Int64
─────┼─────────────────────
1 │ 2 2 3
2 │ 3 7 3
finally you could do the following using the indexing syntax:
julia> df[all.(!=(-1), eachrow(df)), :]
2×3 DataFrame
Row │ A B C
│ Int64 Int64 Int64
─────┼─────────────────────
1 │ 2 2 3
2 │ 3 7 3