Extract values from nested object in plsql using Apex - plsql

Question

I have this employee object and I need to store every value into variables.
I am wondering if it is an easy or smart way to get the values from nested objects.
I know I can get the values in this way:
v_first_name := APEX_JSON.get_varchar2(p_path => 'employee.firstName')
but how can I retrieve the values from address object or from options object?
Apex version 20.1.
{
"employee":{
"firstName":"John",
"lastName":"Smith",
"email":"jsmith#test.com",
"phoneNumber":"‎[phone]",
"address":{
"street":"1527 Pond Reef Rd",
"city":"Ketchikan",
"state":"ALaska",
"stateShort":"AK",
"zipCode":99901,
"country":"USA"
},
"categories":[
{
"categoryID":1,
"categoryName":"Example1",
"options":{
"ind_1":1,
"ind_2":0,
"ind_3":0
}
},
{
"categoryID":2,
"categoryName":"Example",
"options":{
"ind_1":1,
"ind_2":1,
"ind_3":1
}
}
]
}
}

Answer 1

address is just a nested json object so you can use the "dot" notation. categories is an array so you need to loop through the individual elements. Here is an example.
SET SERVEROUTPUT ON
DECLARE
l_json_text VARCHAR2(32767);
l_count PLS_INTEGER;
l_members WWV_FLOW_T_VARCHAR2;
l_paths APEX_T_VARCHAR2;
l_exists BOOLEAN;
l_json_values apex_json.t_values;
BEGIN
l_json_text := '
{
"employee":{
"firstName":"John",
"lastName":"Smith",
"email":"jsmith#test.com",
"phoneNumber":"‎[phone]",
"address":{
"street":"1527 Pond Reef Rd",
"city":"Ketchikan",
"state":"ALaska",
"stateShort":"AK",
"zipCode":99901,
"country":"USA"
},
"categories":[
{
"categoryID":1,
"categoryName":"Example1",
"options":{
"ind_1":1,
"ind_2":0,
"ind_3":0
}
},
{
"categoryID":2,
"categoryName":"Example",
"options":{
"ind_1":1,
"ind_2":1,
"ind_3":1
}
}
]
}
}
';
apex_json.parse(
p_values => l_json_values,
p_source => l_json_text
);
DBMS_OUTPUT.put_line('----------------------------------------');
if apex_json.does_exist(p_path => 'employee.address.street',p_values => l_json_values) then
dbms_output.put_line('address: '||apex_json.get_varchar2(p_path => 'employee.address.street', p_values => l_json_values));
end if;
DBMS_OUTPUT.put_line('----------------------------------------');
DBMS_OUTPUT.put_line('----------------------------------------');
if apex_json.does_exist(p_path => 'employee.categories',p_values => l_json_values) then
dbms_output.put_line(APEX_JSON.get_count(p_path => 'employee.categories', p_values => l_json_values) || ' Categories found');
FOR r IN 1 .. APEX_JSON.get_count(p_path => 'employee.categories', p_values => l_json_values) LOOP
DBMS_OUTPUT.put_line('categoryName: '||apex_json.get_varchar2(p_path => 'employee.categories[%d].categoryName', p0 => r, p_values => l_json_values));
DBMS_OUTPUT.put_line('options.ind_1: '||apex_json.get_varchar2(p_path => 'employee.categories[%d].options.ind_1', p0 => r, p_values => l_json_values));
END LOOP;
end if;
DBMS_OUTPUT.put_line('----------------------------------------');
END;
/
----------------------------------------
address: 1527 Pond Reef Rd
----------------------------------------
----------------------------------------
2 Categories found
categoryName: Example1
options.ind_1: 1
categoryName: Example
options.ind_1: 1
----------------------------------------
PL/SQL procedure successfully completed.