Why Common Lisp CLOS matches on a method where the arguments are the wrong class? - common-lisp

Question

I am trying to learn CLOS and bumped into this surprise. I have those 3 action methods that seemingly incorrectly match on my arguments. When I run tryme function, why the action marked with the last argument being ':c' does not trigger the expected error? What am I doing wrong? Or is it an SBCL bug?
(eval-when (:compile-toplevel :load-toplevel :execute)
(ql:quickload '(alexandria serapeum defclass-std)))
;; (load "~/AAA//clos-turnstile.lisp")
(in-package "CL-USER")
(shadowing-import 'defclass-std::defclass/std)
;;; -----------------------------------------------------------------------------------------
(defclass/std current-state () ())
(defclass/std locked (current-state) ())
(defclass/std unlocked (current-state) ())
(defclass/std input () ())
(defclass/std icoin (input) ())
(defclass/std ipush (input) ())
(defclass/std turnstile ()
((state :std (make-instance 'locked))))
(defgeneric action (turnstile state i msg)
(:documentation "action for our FSM"))
(defmethod action ((turnstile turnstile) (any-state T) (any-input T) (msg T))
(error "0 unmatched action for ~S ~S ~a" any-state any-input msg))
(defmethod action ((turnstile turnstile) (locked current-state) (i icoin) (msg T))
(warn "1 lock coin unlock ~S" msg))
(defmethod action ((turnstile turnstile) (unlocked current-state) (i ipush) (msg T))
(warn "2 unlock push lock ~s" msg))
(defparameter *turnstile* (make-instance 'turnstile))
(defun show-me ()
(format t "=== ~S~%" *turnstile*))
(defun tryme ()
(show-me)
(action *turnstile* (make-instance 'locked) (make-instance 'icoin) :a)
(show-me)
(action *turnstile* (make-instance 'unlocked) (make-instance 'ipush) :b)
(show-me)
;; why this does not give the error? I have swapped the argument types.
(action *turnstile* (make-instance 'unlocked) (make-instance 'icoin) :c)
(show-me)
(action *turnstile* (make-instance 'locked) (make-instance 'icoin) :d)
(show-me)
(action *turnstile* (make-instance 'unlocked) (make-instance 'ipush) :e)
(show-me)
*turnstile*)
Suspicion
I suspect I should have:
(locked locked) instead of (locked current-state)
in the method definition, but how do I avoid such mistakes?

Answer 1

In what you expected to be an error, you were calling action on objects of classes turnstile, unlocked and icoin (and :c which is a keyword, but none of your methods specializes on this argument). But unlocked is a subclass of current-state ! So the call matches
(defmethod action ((turnstile turnstile) (locked current-state) (i icoin) (msg T))
(warn "1 lock coin unlock ~S" msg))
Remember that in a defmethod lambda-list, each specialized argument has the form (var-name class-name) (or some other combinations, e.g. using eql or classes themselves rather than their name ...)
Hence,
(defmethod action ((turnstile turnstile) (locked current-state) (i icoin) (msg T))
(warn "1 lock coin unlock ~S" msg))
(defmethod action ((turnstile turnstile) (unlocked current-state) (i ipush) (msg T))
(warn "2 unlock push lock ~s" msg))
only differ on their third argument (ipush/icoin), and not the current-state.

Answer 2

With the modified arguments of the method definitions, I get the expected error.
(defmethod action ((turnstile turnstile) (any-state T) (any-input T) (msg T))
(error "0 unmatched action for ~S ~S ~a" any-state any-input msg))
(defmethod action ((turnstile turnstile) (locked locked) (i icoin) (msg T))
(warn "1 lock coin unlock ~S" msg))
(defmethod action ((turnstile turnstile) (unlocked unlocked) (i ipush) (msg T))
(warn "2 unlock push lock ~s" msg))