gnuplot - an epslatex terminal does not plot the x-label - plot

Question

I have this small MWE
set title font "Monospaced,13"
set grid
f(x) = 5 * log(x) / log(2)
g(x) = 5 + sqrt(5 + x)
F = '$5 \log_2(x)$'
G = '$5 + \sqrt{5 + x}$'
# set yrange [0:300]
set xrange [0:4000]
set xlabel 'My Label'
set style line 1 linecolor rgb '#a82828' linetype 1 linewidth 5 pointtype 5 pointsize 1.5
set style line 2 linecolor rgb '#516db0' linetype 1 linewidth 5 pointtype 9 pointsize 1.5
plot f(x) title F with lines ls 1, g(x) title G with lines ls 2
set terminal epslatex background rgb "grey" standalone size 10.0cm,10.0cm color colortext
set output 'RunTimeComparisonTreeIndexed.tex'
set style rect fc rgb "white" fs
set object 1 rectangle from screen 0,0 to screen 1,1 behind
set key left top box lt -1 lw 2 opaque
replot
exit
The above script relies on this TeX-post.
It gives me:
(Note that the x-label "My Label" is missing.)
What am I missing here?
Edit
I use the following LaTeX snippet for including the plot PDF file (see the linked TeX.StackExchange post):
\begin{figure}[!h]
\centering
%\setlength{\voffset}{0cm}
%\setlength{\hoffset}{0cm}
\includepdf[pages={1},pagecommand={},width=0.5\textwidth]{RunTimeComparisonTreeIndexed.pdf}
%\setlength{\voffset}{- 10cm}
%\setlength{\hoffset}{-10cm}
\label{fig:rtcti}
\caption{Hello}
\end{figure}

Answer 1

I'm not "fluent" in LaTeX, so this was also a good exercise for me and will be a memory aid for myself.
Use the terminal cairolatex and directly create a PDF with TeX text formatting without detour via .eps. I used MiKTeX and pdflatex under Win10. gnuplot will create two files (SO74149797.tex and SO74149797.pdf).
Script: (requires gnuplot>=5.4.2 for fillcolor for keybox)
### create pdf with TeX text formatting via cairolatex
reset session
f(x) = 5 * log(x) / log(2)
g(x) = 5 + sqrt(5 + x)
F = '$5 \log_2(x)$'
G = '$5 + \sqrt{5 + x}$'
set title font "Monospaced,13"
set xrange [0:4000]
set xlabel 'My Label'
set grid
set key left top box lt -1 lw 2 opaque fc "grey" # fillcolor option fc for gnuplot>=5.4.2
set key width 1 spacing 1.5
set style line 1 linecolor rgb '#a82828' linetype 1 linewidth 5 pointtype 5 pointsize 1.5
set style line 2 linecolor rgb '#516db0' linetype 1 linewidth 5 pointtype 9 pointsize 1.5
set terminal cairolatex pdf input size 10.0cm,10.0cm color colortext
set output 'SO74149797.tex'
plot f(x) title F with lines ls 1, \
g(x) title G with lines ls 2
set output
### end of script
LaTeX: (important to add these packages)
\documentclass[a4paper,10pt]{article}
\usepackage{graphicx}
\usepackage[cp1252]{inputenc}
\usepackage{color}
\begin{document}
\input{SO74149797}
\end{document}
Result: (screenshot from final PDF document)