Try Catch in Xquery not working in MarkLogic - xquery

Question

I am using below code to copy documents related to specified collection from one database to another database.
In my try block I am returning to delete all the documents after successful copy. And in the catch just to print the exception .
But it gives me a syntax error which I am not able to figure out. Can someone please help me in this -
xquery version "1.0-ml";
for $doc in cts:search(doc(), cts:collection-query('Test'))
let $docuri := $doc/base-uri()
let $collections := xdmp:document-get-collections($docuri)
let $permissions := xdmp:document-get-permissions($docuri)
let $document-insert-options :=
<options xmlns="xdmp:document-insert">
<permissions>{$permissions}</permissions>z
<collections>{
<collection>{$collections}</collection>
}
</collections>
</options>
let $db-name := "Final"
let $invoke-function-options :=
<options xmlns="xdmp:eval">
<database>{ xdmp:database($db-name) }</database>
<commit>auto</commit>
</options>
return
try {
xdmp:invoke-function(
function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
$invoke-function-options
);
return xdmp:document-delete($doc)
}
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }

Answer 1

Michael and Rob both have good points, but there are a few more issues.
MarkLogic does complain about the extra 'z' in the $document-insert-options. Get rid of that.
MarkLogic will also complain about the fact you are passing in $doc instead of $docuri into xdmp:document-delete. So change that as well.
Last is the semi-colon bit. MarkLogic does support that, but only on top-level. Using Michael suggestion, insert and delete might happen in parallel. Using Rob's suggestion of an extra 'let $_ :=', and removing ';' will cause MarkLogic to first insert, and delete second. I think that is what you are after.
Running the following against a random database from QC ('Fab' will do), works fine on my end:
xquery version "1.0-ml";
xdmp:document-insert('/test.json', object-node{"foo":"bar"}, map:entry("collections", "Test"))
;
xquery version "1.0-ml";
for $doc in cts:search(doc(), cts:collection-query('Test'))
let $docuri := $doc/base-uri()
let $collections := xdmp:document-get-collections($docuri)
let $permissions := xdmp:document-get-permissions($docuri)
let $document-insert-options :=
<options xmlns="xdmp:document-insert">
<permissions>{$permissions}</permissions>
<collections>{
<collection>{$collections}</collection>
}
</collections>
</options>
let $db-name := "Documents"
let $invoke-function-options :=
<options xmlns="xdmp:eval">
<database>{ xdmp:database($db-name) }</database>
<commit>auto</commit>
</options>
return
try {
let $_ := xdmp:invoke-function(
function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
$invoke-function-options
)
return xdmp:document-delete($docuri)
}
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }
HTH!

Answer 2

What is the error?
Offhand this block looks wrong:
let $document-insert-options :=
<options xmlns="xdmp:document-insert">
<permissions>{$permissions}</permissions>z
<collections>{
<collection>{$collections}</collection>
}
</collections>
</options>
You have a z floating out there after </permissions> which could be breaking schema validation of the options node.
This also could be wrong:
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }
You may need to explicitly return a Sequence like so:
catch ($exception) {
("Problem loading file, received the following exception: ",
$exception)}
This also seems odd to me:
try {
xdmp:invoke-function(
function(){ xdmp:document-insert($docuri, $doc, $document-insert-
options)},
$invoke-function-options
);
return xdmp:document-delete($doc)
}
This breaks FLWOR by trying to use a multi-statement transaction with the ; .
Instead try:
try {
let $_ := xdmp:invoke-function(
function(){ xdmp:document-insert($docuri, $doc, $document-insert-
options)},
$invoke-function-options
)
return xdmp:document-delete($doc)
}

Answer 3

XQuery doesn't have semicolon-delimited statements, nor does it have any instruction or expression that starts with the keyword "return".
xdmp:invoke-function(
function(){ xdmp:document-insert($docuri, $doc, $document-insert-options)},
$invoke-function-options
);
return xdmp:document-delete($doc)
}
catch ($exception) {
"Problem loading file, received the following exception: ",
$exception }
Replace the "; return" by a comma (",").
Marklogic may also have special rules for invoking functions with side-effects; I wouldn't know about that area.