Creating a friendly name from a substring in kusto? - azure-data-explorer

Question

I have the following dataset in kusto:
let data = datatable(Timestamp:datetime, Name:string, Value:int)
[
datetime(2022-02-18 10:00:00 AM), "AX_100A_A00", 100,
datetime(2022-02-18 10:01:00 AM), "BX_101B_B00", 200,
datetime(2022-02-18 10:02:00 AM), "CX_102C_C00", 300,
datetime(2022-02-18 10:03:00 AM), "DX_103D_D00", 400,
datetime(2022-02-18 10:04:00 AM), "EX_104E_E00", 500,
];
data
| summarize result = max(Value) by Floor_Name = substring(Name, 3, 4)
To illustrate what I am trying achieve here. Between the two underscores there is a code which represents a specific Location. What I need is to replace each value between those 2 underscores into a friendly name. Please note this is just sample. In my real case scenario I need to be replacing 50 names. I don't know if I should be defining a variable as dictionary which takes the previous name as KEY and the new name as VALUE then check for the existing key and replace it. I don't know if there is a better way to do it. I need to achieve the following:
100A --> New York
101B --> Geneva
102C --> France
103D --> US
104E --> Canada

Answer 1

The dynamic data type
or
bag_pack(), pack()
let data = datatable(Timestamp:datetime, Name:string, Value:int)
[
datetime(2022-02-18 10:00:00 AM), "AX_100A_A00", 100,
datetime(2022-02-18 10:01:00 AM), "BX_101B_B00", 200,
datetime(2022-02-18 10:02:00 AM), "CX_102C_C00", 300,
datetime(2022-02-18 10:03:00 AM), "DX_103D_D00", 400,
datetime(2022-02-18 10:04:00 AM), "EX_104E_E00", 500,
];
let mydict = dynamic(
{
"100A":"New York"
,"101B":"Geneva"
,"102C":"France"
,"103D":"US"
,"104E":"Canada"
}
);
data
| summarize result = max(Value) by Floor_Name = tostring(mydict[substring(Name, 3, 4)])
Floor_Name
result
New York
100
Geneva
200
France
300
US
400
Canada
500
Fiddle