How to handle leap years in Ada - ada

Question

I'm supposed to do a program that handles the dates of a year. I'm having a problem with handling the leap year in a good way. I'm not going to post the entire code because it'll be too much. My program runs but I don't like how my last if statement looks.
Information about months and leap years:
Month: Jan Feb Mar Apr May Jun Jul Aug Sep Okt Nov Dec
Days : 31 28/29 31 30 31 30 31 31 30 31 30 30
A year is a leap year if it's evenly dividable by 4, but not even when divided by 100. Years are also evenly dividable by 400 leap years. If it's a leap year, February has 29 days instead of 28.
This is my code (only the part I need help with):
Get(Days);
if Days > 31 or Day < 1 then
raise Day_Error;
elsif Day = 31 and (Month = 2 or Month = 4 or Month = 6 or Month = 9 or Month = 11) then
raise Day_Error;
elsif Day = 30 and (Month = 1 or Month = 3 or Month = 5 or Month = 7 or
Month = 8 or Month = 10 or Month = 12) then
raise Day_Error;
end if;
if Day = 29 and Month = 2 then
if Year mod 400 = 0 or (Year mod 4 = 0 and Year mod 100 /= 0) then
null;
else
raise Day_Error;
end if;
end if;
exit;
end;
end loop;
end Day_Procedure;
My concern is the if statement where I put Day = 29 and Month = 2, can this be solved without having the need to put two if statements?

Answer 1

I think a lot can be gained by putting certain tests in subroutines, even if they are only called once. In the code below I have a routine GetMaxDayInMonth(Month, Year) that gives the maximum day for the given month in the given year. The year is necessary only in the case of February, where the maximum allowed day of the month depends on whether it is in a leap year.
For all other months the return value is constant, which I have recorded in a const array MaxDaysInMonth. Only days in February must be treated specially. That treatment has again been stowed away in its own little subroutine GetFebMaxDay(Day, Month), making everything neat and intelligible.
I have used the new Ada equivalent to the C ternary operator cond?a:b, (if cond then a else b):
function GetFebMaxDay(Year: YearT) return DayInMonthT is
begin
return (if IsLeapYear(Year) then 29 else 28);
end GetFebMaxDay;
The test for valid day then is thus reduced to a single function call
Date.Day <= GetMaxDayInMonth(Date.Month, Date.Year);
I have also created distinct types for year, month and day, imposing constraints where possible (max day in month is 31, after all). Many mistakes would have been avoided if programmers had put feet and meters in their own subtypes that need explicit conversion.
Here is the entire program that checks a few borderline dates:
with Ada.Text_IO; use Ada.Text_IO;
procedure DateCheck is
subtype DayInMonthT is Integer range 1..31;
type MonthT is (JAN, FEB, MAR, APR, MAY, JUN, JUL, AUG, SEP, OCT, NOV, DEC);
subtype YearT is Integer;
type DateT is record Year: YearT; Month: MonthT; Day: DayInMonthT; end record;
function IsLeapYear(Y: YearT) return Boolean is
begin
return (Y mod 4 = 0 and Y mod 100 /= 0)
or Y mod 400 = 0;
end IsLeapYear;
function GetFebMaxDay(Year: YearT) return DayInMonthT is
begin
return (if IsLeapYear(Year) then 29 else 28);
end GetFebMaxDay;
function GetMaxDayInMonth(Month: MonthT; Year: YearT) return DayInMonthT is
MaxDaysInMonth: constant array(MonthT) of DayInMonthT :=
( JAN => 31,
FEB => 29,
MAR => 31,
APR => 30,
MAY => 31,
JUN => 30,
JUL => 31,
AUG => 31,
SEP => 30,
OCT => 31,
NOV => 30,
DEC => 31 );
begin return (if Month = FEB then GetFebMaxDay(Year) else MaxDaysInMonth(Month)); end;
function IsValidateDate(Date: DateT) return Boolean is
begin
return Date.Day <= GetMaxDayInMonth(Date.Month, Date.Year);
end;
Dates: array (1..6) of DateT := (others => (0, JAN, 1));
begin
Dates(1) := (2021, FEB, 28);
Dates(2) := (2021, FEB, 29);
Dates(3) := (2021, FEB, 30);
Dates(4) := (2000, FEB, 31);
-- Dates(4) := (2000, FEB, 32); -- raises warning, fails with constraint error
Dates(5) := (2000, FEB, 29);
Dates(6) := (1900, FEB, 29);
for i in Dates'Range loop
Put("Date ");
Put(Dates(i).Year'Image);
Put("-");
Put(Dates(i).Month'Image);
Put("-");
Put(Dates(i).Day'Image);
Put(": Valid date? ");
Put_Line(IsValidateDate(Dates(i))'Image);
end loop;
end DateCheck;
Sample session:
$ gnatmake -gnatwa datecheck.adb && ./datecheck.exe
gcc -c -gnatwa datecheck.adb
gnatbind -x datecheck.ali
gnatlink datecheck.ali
Date 2021-FEB- 28: Valid date? TRUE
Date 2021-FEB- 29: Valid date? FALSE
Date 2021-FEB- 30: Valid date? FALSE
Date 2000-FEB- 31: Valid date? FALSE
Date 2000-FEB- 29: Valid date? TRUE
Date 1900-FEB- 29: Valid date? FALSE