Difference between two dates in years days hours minutes format [duplicate] - datetime

Question

This question already has answers here:
Difference between two dates expressed as years, months, days (in one column)
(5 answers)
Closed 1 year ago.
I am trying to find out difference between two days "xx years xx days xx hours xx minutes" format. My start date is in A column and end date is in B. Calculating difference in C column.
I am using B1-A1 formula in C column and using custom format "yy" years "dd" days "hh" hours "mm" minutes" in C column. It works fine if the start and end years are different. But if it is same, C column reporting incorrect years and days. (showing as 99 years and 30 days).
How to fix it ?
Sample google sheet link

Answer 1

Your B2 - A2 formula is actually getting the correct result — it is a dateserial value that represents the difference between the two moments in units of days.
The problem is with the custom number format you are using. It refers to calendar time, while you would need elapsed time. Unfortunately, Google Sheets apparently only supports elapsed time in units of hours, minutes and seconds.
If a text string result is OK with you, use this:
=datedif(A2, B2, "y") & " years " & datedif(A2, B2, "d") - 365 * datedif(A2, B2, "y") & " days " & text(B2 - A2 - int(B2 - A2), "HH ""hours"" mm ""minutes""")
The formula assumes that all years are 365 days long, which will not be correct when the date span crosses a leap day.
To get the average elapsed time, evaluate =B2 - A2 for all rows with an array formula, then calculate the average of those results, and finally format the result to your liking, like this:
=arrayformula( average( if( B2:B + A2:A, B2:B - A2:A, iferror(1/0) ) ) )
=datedif(0, G2, "y") & " years " & datedif(0, G2, "d") - 365 * datedif(0, G2, "y") & " days " & text(G2 - 0 - int(G2 - 0), "H ""hours"" m ""minutes""")
See cells F2:G2 in your sample spreadsheet.
See this answer for an explanation of how date and time values work in spreadsheets.

Answer 2

A bit long, but it works. Would like to try TEXT but I have additional conditions for the days since it is tricky due to how sheets calculate the difference when actually they have different days per months. You need to consider the days per months as it is unique.
Formula:
=datedif(A2, B2, "y")&" years "
&if(day(B2) >= day(A2),
if(index(split(B2, " "), ,2) >= index(split(A2, " "), ,2),
day(B2) - day(A2),
day(B2) - day(A2) - 1),
if(index(split(B2, " "), ,2) >= index(split(A2, " "), ,2),
day(eomonth(B2, -1)) + day(B2) - min(day(A2), day(eomonth(B2, -1))),
day(eomonth(B2, -1)) + day(B2) - min(day(A2), day(eomonth(B2, -1))) -1))&" days "
&hour(B2 - A2)&" hours "
&minute(B2 - A2)&" minutes"
Output:
Note:
Formula took care of formatting.
Days have a very complicated formula due to different days per months. But this should show a more accurate answer
index(split(B2, " "), ,2) >= index(split(A2, " "), ,2) is added on the original formula to consider later time on start date, reducing the days by 1 if that happens
Reference:
https://stackoverflow.com/a/55222439/14606045

Answer 3

try:
=INDEX(IFERROR(TRIM(REGEXREPLACE(
TEXT( DATEDIF(A2:A, B2:B, "Y"), "0#")&CHOOSE(MATCH( DATEDIF(A2:A, B2:B, "Y"), {0,1,2})," years ", " year ", " years ")&
TEXT(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), "0#")&CHOOSE(MATCH(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), {0,1,2})," days ", " day ", " days ")&
TEXT( TEXT(B2:B-A2:A, "H"), "0#")& CHOOSE(MATCH(TEXT(B2:B-A2:A, "H") *1, {0,1,2})," hours ", " hour ", " hours ")&
TEXT(INT(TEXT(B2:B-A2:A, "M.S")), "0#")& CHOOSE(MATCH(TEXT(B2:B-A2:A, "M.S")*1, {0,1,2})," minutes"," minute"," minutes"),
"\b0 (year(s)|day(s)|hour(s)|minute(s))", ))))
works with leap years
works with singular
works with plural
works with arrays
works with seconds
works with dates only
works with time only
works with less than a day
works with blank rows
excludes all null values
to remove only leading null values:
=INDEX(IFERROR(TRIM(REGEXREPLACE(
TEXT( DATEDIF(A2:A, B2:B, "Y"), "00")&CHOOSE(MATCH( DATEDIF(A2:A, B2:B, "Y"), {0,1,2})," years ", " year ", " years ")&
TEXT(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), "00")&CHOOSE(MATCH(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), {0,1,2})," days ", " day ", " days ")&
TEXT( TEXT(B2:B-A2:A, "H"), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "H") *1, {0,1,2})," hours ", " hour ", " hours ")&
TEXT(INT(TEXT(B2:B-A2:A, "M.S")), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "M.S")*1, {0,1,2})," minutes"," minute"," minutes"),
"^\b(?:00 years )?(?:00 days )?(?:00 hours )?(?:00 minutes)?", ))))
to NOT remove any null values:
=INDEX(IFERROR(REGEXREPLACE(
TEXT( DATEDIF(A2:A, B2:B, "Y"), "00")&CHOOSE(MATCH( DATEDIF(A2:A, B2:B, "Y"), {0,1,2})," years ", " year ", " years ")&
TEXT(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), "00")&CHOOSE(MATCH(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), {0,1,2})," days ", " day ", " days ")&
TEXT( TEXT(B2:B-A2:A, "H"), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "H") *1, {0,1,2})," hours ", " hour ", " hours ")&
TEXT(INT(TEXT(B2:B-A2:A, "M.S")), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "M.S")*1, {0,1,2})," minutes"," minute"," minutes"),
"^\b00 years 00 days 00 hours 00 minutes", )))
to have it aligned with Mars, Jupiter and Saturn:
=INDEX(IFERROR(REGEXREPLACE(REGEXREPLACE(
TEXT( DATEDIF(A2:A, B2:B, "Y"), "00")&CHOOSE(MATCH( DATEDIF(A2:A, B2:B, "Y"), {0,1,2})," years ", " year ", " years ")&
TEXT(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), "000")&CHOOSE(MATCH(IF(B2:B-A2:A<1,,DATEDIF(A2:A, B2:B, "YD")), {0,1,2})," days ", " day ", " days ")&
TEXT( TEXT(B2:B-A2:A, "H"), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "H") *1, {0,1,2})," hours ", " hour ", " hours ")&
TEXT(INT(TEXT(B2:B-A2:A, "M.S")), "00")&CHOOSE(MATCH(TEXT(B2:B-A2:A, "M.S")*1, {0,1,2})," minutes"," minute "," minutes"),
"^\b00 years 000 days 00 hours 00 minutes", ), "(0)(\d{2})", " $2")))
update:
for average use either:
=INDEX(AVERAGE(IF(B2:B+A2:A, B2:B-A2:A, )))
or:
=INDEX(AVERAGE(IFERROR(1/(1/(B2:B-A2:A)))))
depends on the sensitivity you need

Answer 4

Put if condition if both values are same then it should be otherwise do subtract
=IF(A1=B1,"0",B1-A1)

Answer 5

This is because the GS considers the zero date to be the first day of its calendar, i.e. 1899-12-30. You can get a correct result with following formula:
=TEXT(DATEDIF(A2,B2,"Y"),"00 \y\ear\s ") &
TEXT(TRUNC(EDATE(B2,-12*(DATEDIF(A2,B2,"Y")))-A2), "00 \da\y\s ") &
TEXT(ABS((B2-TRUNC(B2,0))-(A2-TRUNC(A2,0))+1),"hh \hour\s mm \minut\e\s")
or using arrayformula:
=ArrayFormula(IF(LEN(A2:A),
TEXT(DATEDIF(A2:A,B2:B,"Y"),"00 \y\ear\s ") &
TEXT(TRUNC(EDATE(B2:B,-12*(DATEDIF(A2:A,B2:B,"Y")))-A2:A), "00 \da\y\s ") &
TEXT(ABS((B2:B-TRUNC(B2:B,0))-(A2:A-TRUNC(A2:A,0))+1),"hh \hour\s mm \minut\e\s"),))
The formula takes into account the leap years and calculates elapsed days.