Date-Time Formatting in XSLT 2.0 - datetime

Question

I have an XML which has a field with Date-Time stamp as below:
<?xml version='1.0' encoding='UTF-8'?
<root>
<row>
<Code>A1</Code>
<ID>20202020</ID>
<Date-Changed>April 01, 2021, 1:13 pm</Date-Changed>
</row>
<row>
<Code>A1</Code>
<ID>20202020</ID>
<Date-Changed>April 01, 2021, 1:14 pm</Date-Changed>
</row>
</root>
I need to convert this to a format which the XSLT understands so that I can filter only the rows which have the latest Date-time stamp. I have figured out a way to filter on the records with the latest Date-time stamp. However, the Date-time stamp format in the XML is throwing the logic off where I am filtering on the latest changed record.
What can I do so that my XSLT can understand the Date-time format in the above XML and output the below XML?
<?xml version="1.0" encoding="UTF-8"?>
<root xmlns:xs="http://www.w3.org/2001/XMLSchema">
<row>
<Code>A1</Code>
<ID>1234ABCD</ID>
<Date-Changed>2021-04-01T13:14:00</Date-Changed>
</row>
</root>
My XSLT looks like below:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="xml" indent="yes" omit-xml-declaration="no"/>
<xsl:template match="/">
<root>
<xsl:for-each select="root">
<xsl:for-each-group select="row" group-by="(concat(ID, Code))">
<xsl:variable name="Mod_Dt">
<xsl:value-of select="max(current-group()/Date-Changed/xs:dateTime(.))"/>
</xsl:variable>
<row>
<Code>
<xsl:value-of select="(current-group()[Date-Changed=$Mod_Dt]/Code)"/>
</Code>
<ID>
<xsl:value-of select="(current-group()[Date-Changed=$Mod_Dt]/ID)"/>
</ID>
<Date-Changed>
<xsl:value-of select="(current-group()[Date-Changed=$Mod_Dt]/Date-Changed)"/>
</Date-Changed>
</row>
</xsl:for-each-group>
</xsl:for-each>
</root>
</xsl:template>
</xsl:stylesheet>
Any help will be greatly appreciated!

Answer 1

You can define a function to convert the given string to a valid dateTime - for example:
<xsl:function name="my:string-to-dateTime">
<xsl:param name="string"/>
<!-- extract components -->
<xsl:variable name="parts" select="tokenize($string, ',\s|\s|:')"/>
<!-- adjust -->
<xsl:variable name="m" select="index-of(('Jan', 'Feb', 'Mar', 'Apr', 'May', 'Jun', 'Jul', 'Aug', 'Sep', 'Oct', 'Nov', 'Dec'), substring($parts[1], 1, 3))" />
<xsl:variable name="H12" select="number($parts[4]) mod 12" />
<xsl:variable name="H" select="if($parts[6]='pm') then $H12 + 12 else $H12" />
<!-- output -->
<xsl:sequence select="xs:dateTime(concat($parts[3], format-number($m, '-00') , '-', $parts[2], format-number($H, 'T00'), format-number(number($parts[5]), ':00'), ':00'))" />
</xsl:function>
Demo: https://xsltfiddle.liberty-development.net/6qaHaQz/2

Answer 2

It looks as if it might be amenable to parsing using the parse-ietf-date() function in XSLT 3.0