Limit the number of joined rows in Kusto / KQL / ADX - azure-data-explorer

Question

Given the following Kusto query, is it possible to limit the result set so only the two cities with highest population per country are retrieved?
My real scenario is for sure a lot more complex but I've spent several hours now to figure out how I could do this. I tried with the top-nested operator but this operator actually changes the column layout by aggregating on a single column and not just reduces the amount of fetched rows by grouping criteria.
let population=datatable (name: string, population: int64) [
"New York", 4478934739,
"Washington DC", 412165236,
"Miami", 124437843,
"Berlin", 222347384,
"Munich", 6783434,
"Hamburg", 6000033
];
let country=datatable (name: string, country: string) [
"New York", "US",
"Washington DC", "US",
"Miami", "US",
"Berlin", "DE",
"Munich", "DE",
"Hamburg", "DE"
];
population
| join kind=inner country on name

Answer 1

Would this work?
Note that the partition operator is currently limited to 64 values (this is a temporary limitation)
let Populations=datatable (name: string, population: int64) [
"New York", 4478934739,
"Washington DC", 412165236,
"Miami", 124437843,
"Berlin", 222347384,
"Munich", 6783434,
"Hamburg", 6000033
];
let Countries=datatable (name: string, country: string) [
"New York", "US",
"Washington DC", "US",
"Miami", "US",
"Berlin", "DE",
"Munich", "DE",
"Hamburg", "DE"
];
Countries
| partition by country(
lookup Populations on name
| top 2 by population
)
If you can't use partition due to the number of partitions limitation here is an alternative:
let Populations=datatable (name: string, population: int64) [
"New York", 4478934739,
"Washington DC", 412165236,
"Miami", 124437843,
"Berlin", 222347384,
"Munich", 6783434,
"Hamburg", 6000033
];
let Countries=datatable (name: string, country: string) [
"New York", "US",
"Washington DC", "US",
"Miami", "US",
"Berlin", "DE",
"Munich", "DE",
"Hamburg", "DE"
];
Countries
| lookup Populations on name
| order by country, population desc
| extend rn = row_number(0, country != prev(country))
| where rn <=1
| project country, name, population