Stata plot with information from multiple variables - plot

Question

I have 10 binary variables- var1, var2,...,var10 answering "yes" or "no" (1 or 0) to a certain question, but under different conditions. I want to create a barplot in stata that shows me the proportion of people who answered "no" for each of the variables (a single plot). How can I do this? If I use the regular barplot command for frequencies
graph bar, over(varlist)
I get an error because over() only takes in a single variable, not a varlist. Something like this is pretty easy to do in R or Python, but I'm not sure how to do this in stata. My data looks something like below:
+-------------------------------+
| id var1 var2 var3 |
|-------------------------------|
1. | 1 0 0 1 |
2. | 2 1 1 1 |
3. | 3 0 1 1 |
+-------------------------------+
As stated, each person has answered 3 questions (rather, the same question presented in three different ways) with "yes" or "no". I want to generate a single barplot with three bars ("var1", "var2", "var3"), each representing the proportion of people who answered no to the question (so 0.67, 0.33, and 0, respectively, in the example data).

Answer 1

There is no reproducible data example here. The Stata tag wiki has very detailed advice on how to give data examples.
Plotting the fraction of zeros directly does not yield to any trick obvious to me as I write, but here is a work-around. The principles for 10 variables aren't different from those for a four-variable example invented here. The main idea is that the default of graph hbar (or of graph bar or graph dot) is to show means, and the mean of a binary variable is a proportion.
clear
set seed 2803
set obs 10
forval j = 1/4 {
generate var`j' = runiform() > (`j' * 0.2)
}
forval j = 1/4 {
generate nvar`j' = 1 - var`j'
label var nvar`j' "var`j'"
}
graph hbar nvar* , ascategory ytitle(fraction of Nos) name(G1, replace)
statplot nvar*, ytitle(fraction of Nos) name(G2, replace)
The statplot solution (dependent on installing that command using ssc install statplot) is just an alternative. It's a personal view that its immediate result here is closer to a civilised graph than the default of graph hbar. But it's not different in principle and you would get closer by spelling out more options directly for graph hbar.
Using graph hbar rather than graph bar is a personal choice. But if your real data have variable labels or longer names, then space to show either readably for 10 variables could be a medium-sized deal.