Reread command makes distorted animation in gnuplot - plot

Question

I am trying to have a live plot of a datafile that is being dynamically updated inside the main program. I am plotting using the following .plt file
set pm3d map
set xrange[ -6.0000000000000000 : 6.0000000000000000 ]
set yrange[ -6.0000000000000000 : 6.0000000000000000 ]
sp'fpf.dat'u 1:2:3 w pm3d
pause 0.1
reread
But on running the program, the animation I am obtaining is getting distorted.
I think the problem is taking place because as the file is being dynamically updated, even before gnuplot is able to generate the full plot using the temporarily stored data, the file is being updated again and again. What is the solution?

Answer 1

First, I suggest not to use reread but instead create a loop that you have more control over.
set pm3d
set view map
while (some-condition) {
sp'fpf.dat'u 1:2:3 w pm3d
pause 0.1
}
Now several options come to mind
1) The program that is creating the data could over-write the previous data in place
rather than creating (or truncating) the file each time.
2) Instead of putting gnuplot in a loop based on refreshing every tenth of a second, use explicit synchronization between the data file creation and the subsequent plot. There are many ways you might do this depending on your environment and your control over the programs involved. For example you might replace the pause statement with a second loop that spins until the data file modification time changes (specific commands available depend on your OS and shell)
oldtime = timestamp
while (timestamp == oldtime) {
timestamp = system( "stat --format=%X file.dat" )
pause 0.1
}
# we exited the previous loop because the file timestamp changed
3) You could try using multiplot mode (set multiplot before starting to loop), so that each new plot is drawn on top of the previous plot rather than replacing it. If your diagnosis is correct that the white sections are due to incomplete data, then instead of a blank area you will see the content of the previous plot.