How to build or condition on datasorce in the code? - axapta

Question

I have two tables. Lets call them Table1 and Table2. I need to create in the code query like.
Select * from Table1
exists join Table2 where
Table1.Key == Table2.Key &&
(Table1.A == '1' || Table2.C == '2')
So to transfer to code I tried:
Query q;
QueryBuildDataSource qbd;
QueryBuildDataSource ofQbds;
QueryBuildRange qbr;
str range;
Table1 test;
QueryRun qr;
q = new Query();
qbd = q.addDataSource(tableNum(Table1));
qbd .name('Table1');
ofQbds = qbd.addDataSource(tableNum(Table2));
ofQbds.name('Table2');
ofQbds.addLink(fieldNum(Table1, Key), fieldNum(Table2, Key));
ofQbds.joinMode(JoinMode::InnerJoin);
range = strFmt('%1.%2 == %3 OR %4.%5 == %6', qbd.name(), 'A', '1',
ofQbds.name(), 'C', '5');
info(range);
ofQbds.addRange(fieldName2id(tableNum(Table1 ), 'A')).value(range);
qr = new QueryRun(q);
while (qr.next())
{
test = qr.get(test.TableId);
info(test.A + ','+test.Key);
}
info('done');
But the or condition does not work properly.
For example If I have values
Table1
A,Key
1,1
2,2
3,3
Table2
C,Key
2,2
I would expect 2 results from Table1
1,1
2,2
but I get only the first one
Message
Table1.A == 1 OR Table2.C == 2
2,2
done
I tried different joinModes and switching || and OR but nothing I tried yet works.
What I need to change to be able to have or condition in the code?

Answer 1

Try changing this line:
range = strFmt('%1.%2 == %3 OR %4.%5 == %6', qbd.name(), 'A', '1', ofQbds.name(), 'C', '5');
to
range = strFmt('((%1.%2 == %3) || (%4.%5 == %6))', qbd.name(), 'A', '1', ofQbds.name(), 'C', '5');
Don't use sql "or", instead use the x++ "||"
Edit: see http://www.axaptapedia.com/Expressions_in_query_ranges for more information.
Edit 2: This code executes for me in the desired fashion. I would recommend using the most up to date compile-time functions such as tableNum() and fieldNum() etc.
Query q;
QueryBuildDataSource qbd;
QueryBuildDataSource ofQbds;
QueryBuildRange qbr;
str range;
QueryRun qr;
CustTable custTable;
CustGroup custGroup;
q = new Query();
qbd = q.addDataSource(tableNum(CustTable));
ofQbds = qbd.addDataSource(tableNum(CustGroup));
ofQbds.addLink(fieldNum(CustTable, CustGroup), fieldNum(CustGroup, CustGroup));
ofQbds.joinMode(JoinMode::InnerJoin);
range = strFmt('((%1.%2 == %3) || (%4.%5 == %6))',
tableStr(CustTable),
fieldStr(CustTable, AccountNum),
'000001',
tableStr(CustGroup),
fieldStr(CustGroup, CustGroup),
'UAC');
info(range);
ofQbds.addRange(fieldNum(CustTable, AccountNum)).value(range);
qr = new QueryRun(q);
while (qr.next())
{
custTable = qr.get(tableNum(CustTable));
info(custTable.AccountNum + ',' +custTable.CustGroup);
}