Send mail via mailgun with attachment in delphi - http

Question

I try to send mail with added attachment. Mail arrives to the addresse withouth an attachment. I use api access in delphi (indy). Can anyone help me ? My code:
try
IdHTTP1.Request.CharSet := 'utf-8';
IdHTTP1.Request.ContentType := 'multipart/form-data';
IdHTTP1.Request.BasicAuthentication := True;
IdHTTP1.Request.Username := 'api';
IdHTTP1.Request.Password := 'my pass';
Parametri := TIdMultiPartFormDataStream.Create;
Parametri.AddFormField('from', UTF8Encode('Excited user<excited#sandbox.mailgun.org>'), 'utf-8').ContentTransfer := '8bit';
Parametri.AddFormField('to','to#mail.com');
Parametri.AddFormField('subject', UTF8Encode('xy: sub...'), 'utf-8').ContentTransfer := '8bit';
Parametri.AddFormField('text', UTF8Encode('Here is my text...'), 'utf-8').ContentTransfer := '8bit';
Parametri.AddFile('ABC.pdf', 'c:\ABC.pdf', '');
Memo1.Text := IdHTTP1.Post( 'https://api.mailgun.net/v3/sandbox.mailgun.org/messages', Parametri);
finally
Parametri.Free;
end;
Thank you,
b.

Answer 1

Per the MailGun API documentation, each email attachment needs to be sent in a MIME field named 'attachment'. But when calling AddFile(), you are not naming the field 'attachment', you are naming it 'ABC.pdf' instead.
Change this line:
Parametri.AddFile('ABC.pdf', 'c:\ABC.pdf', '');
To this instead:
Parametri.AddFile('attachment', 'c:\ABC.pdf');
Alternatively, the documentation also states that MailGun supports SMTP, so you could use TIdSMTP and TIdMessage instead of using TIdHTTP and TIdMultipartFormDataStream, and let TIdMessage handle the MIME formatting for you, eg:
IdSMTP1.Host := 'smtp.mailgun.org';
IdSMTP.Username := 'api';
IdSMTP.Password := 'my pass';
IdMessage1.Clear;
IdMessage1.From.Name := 'Excited user';
IdMessage1.From.Address := 'excited#sandbox.mailgun.org';
IdMessage1.Recipients.EmailAddresses := 'to#mail.com';
IdMessage1.Subject := 'xy: sub...';
IdMessage1.ContentType := 'multipart/mixed';
with TIdText.Create(IdMessage1.MessageParts, nil) do
begin
Body.Text := 'Here is my text...';
ContentType := 'text/plain';
CharSet := 'utf-8';
ContentTransfer := '8-bit';
end;
TIdAttachmentFile.Create(IdMessage1.MessageParts, 'c:\ABC.pdf');
IdSMTP1.Connect;
try
IdSMTP1.Send(IdMessage1);
finally
IdSMTP1.Disconnect;
end;
Or:
IdSMTP1.Host := 'smtp.mailgun.org';
IdSMTP.Username := 'api';
IdSMTP.Password := 'my pass';
IdMessage1.Clear;
IdMessage1.From.Name := 'Excited user';
IdMessage1.From.Address := 'excited#sandbox.mailgun.org';
IdMessage1.Recipients.EmailAddresses := 'to#mail.com';
IdMessage1.Subject := 'xy: sub...';
with TIdMessageBuilderPlain.Create do
try
PlainText := 'Here is my text...';
PlainTextCharSet := 'utf-8';
PlainTextContentTransfer := '8-bit';
Attachments.Add('c:\ABC.pdf');
FillMessage(IdMessage1);
finally
Free;
end;
IdSMTP1.Connect;
try
IdSMTP1.Send(IdMessage1);
finally
IdSMTP1.Disconnect;
end;