how can I add a command for my app to rerun - button

Question

I'm trying to get the app to "rerun" when the "return to formula list" button is pushed.
I thought this would work since I basically have it going back to the main list, but once it gets back to the list and another selection is made, it exits the app. this obviously isn't the whole code, I just included the first two options.
--DIVE FORMULAS--
--RUN FORMULA LIST--
set x to item 1 of (choose from list {"Divers consumption at depth", "Free Gas Volume (FGV)", "Cylinder Duration", "Partial Pressure", "Initial Depth", "Cylinder Mixing"})
--DIVERS CONSUMPTION AT DEPTH--
if x is "Divers consumption at depth" then
--VARIABLES--
display dialog "What is divers breathing volume (L/min) (default 35 l/min?" default answer "35"
set varDvol to text returned of result
display dialog "What is divers absolute depth pressure (bar)" default answer ""
set varPbar to text returned of result
--FORMULA--
set answer to varDvol * varPbar
--ANSWER--
display dialog "A diver breathing " & varDvol & " l/min, at an absolute pressure of " & varPbar & " bar, will have a consumption of " & answer & " l/min" as text buttons {"See formula", "Return to formula list", "Exit"}
--OPTIONS--
set response to button returned of result
--SEE FORMULA--
if response = "See formula" then
display dialog "Divers Consumption = Divers Breathing Volume * Absolute pressure of depth (bar)" buttons ("Return to Formula List")
--RETURN TO FORMULA LIST--
set response to button returned of result
if response = "Return to Formula List" then
set x to item 1 of (choose from list {"Divers consumption at depth", "Free gas volume (FGV)", "Cylinder Duration", "Prartial Pressure", "Initial Depth", "Cylinder Mixing"})
end if
--RETURN TO FORMULA LIST--
else if response = "Return to formula list" then
set x to item 1 of (choose from list {"Divers consumption at depth", "Free gas volume (FGV)", "Cylinder Duration", "Prartial Pressure", "Initial Depth", "Cylinder Mixing"})
--EXIT APP--
else if response = "Exit" then
display dialog "Are you sure you wish to exit?" buttons {"Return to Formula List", "Exit"}
set response to button returned of result
if response = "Return to Formula List" then
set x to item 1 of (choose from list {"Divers consumption at depth", "Free gas volume (FGV)", "Cylinder Duration", "Prartial Pressure", "Initial Depth", "Cylinder Mixing"})
end if
else if response = "EXIT" then
quit
end if
--FREE GAS VOLUME--
else if x is "Free gas volume (FGV)" then
--VARIABLES--
display dialog "What is the floodable volume of the cylinder (L)?" default answer ""
set varFvol to text returned of result
display dialog "What is the pressure of the cylinder (bar)?" default answer ""
set varCylPress to text returned of result
--FORMULA--
set answer to varFvol * varCylPress
--ANSWER--
display dialog "The free gas volume is (L)" & answer as text buttons {"See formula", "Return to formula list", "Exit"}
--OPTIONS--
set response to button returned of result
--SEE FORMULA--
if response = "See formula" then
display dialog "FGV = Floodable volume of cylinder * Pressure of cylinder (bar)"
--RETURN TO FORMULA LIST--
else if response = "Return to formula list" then
set x to item 1 of (choose from list {"Divers consumption at depth", "Free gas volume (FGV)", "Cylinder Duration", "Partial Pressure", "Initial Depth", "Cylinder Mixing"})
--EXIT APP--
else if response = "Exit" then
#do a third thing
end if
like I said, the "return to formula list" button works, but when I make another choice from the main list, the app closes, it won't go on to the next chosen function, which is what I'm looking for

Answer 1

You should look into the use of handlers (subroutines), otherwise you are going to get lost fairly quickly as you implement the other options or expand features in the script.
One way you can do this is by restructuring the script, putting the main list into a repeat statement, and having each choice run in a separate handler. These handlers would only be concerned with their specific function (also handy for viewing and debugging), and could return the button of the last dialog for the main loop to use, for example:
on run -- main
repeat -- forever
set choice to (choose from list {"Divers consumption at depth", "Free Gas Volume (FGV)", "Cylinder Duration", "Partial Pressure", "Initial Depth", "Cylinder Mixing"} cancel button name "Exit") as text — just one item
if choice is "Divers consumption at depth" then
set theResult to consumption()
else if choice is "Free Gas Volume (FGV)" then
set theResult to volume()
else if choice is "Cylinder Duration" then
set theResult to duration()
else if choice is "Partial Pressure" then
set theResult to pressure()
else if choice is "Initial Depth" then
set theResult to depth()
else if choice is "Cylinder Mixing" then
set theResult to mixing()
end if
if choice is "false" or theResult is "Exit" then -- exit
set response to (display dialog "Are you sure you wish to exit?" buttons {"Return to Formula List", "Exit"})
if button returned of response is "Exit" then exit repeat
end if
end repeat
end run
on consumption() -- Divers consumption at depth
--VARIABLES--
set response to (display dialog "What is divers breathing volume (L/min) (default 35 l/min?" default answer "35" buttons {"Exit", "OK"} default button 2)
if button returned of response is "Exit" then return "Exit"
set varDvol to text returned of response
set response to (display dialog "What is divers absolute depth pressure (bar)" default answer "1" buttons {"Exit", "OK"} default button 2)
if button returned of response is "Exit" then return "Exit"
set varPbar to text returned of response
--FORMULA--
set answer to varDvol * varPbar
--ANSWER--
set response to (display dialog "A diver breathing " & varDvol & " l/min, at an absolute pressure of " & varPbar & " bar, will have a consumption of " & answer & " l/min" as text buttons {"See formula", "Return to formula list", "Exit"})
--SEE FORMULA--
if button returned of response = "See formula" then
set response to (display dialog "Divers Consumption = Divers Breathing Volume * Absolute pressure of depth (bar)" buttons {"Return to Formula List", "Exit"})
end if
return button returned of response
end consumption
on volume() -- Free Gas Volume (FGV)
set response to (display dialog "volume" buttons {"Exit", "OK"} default button 2)
return button returned of response
end volume
on duration() -- Cylinder Duration
set response to (display dialog "duration" buttons {"Exit", "OK"} default button 2)
return button returned of response
end duration
on pressure() -- Partial Pressure
set response to (display dialog "pressure" buttons {"Exit", "OK"} default button 2)
return button returned of response
end pressure
on depth() -- Initial Depth
set response to (display dialog "depth" buttons {"Exit", "OK"} default button 2)
return button returned of response
end depth
on mixing() -- Cylinder Mixing
set response to (display dialog "mixing" buttons {"Exit", "OK"} default button 2)
return button returned of response
end mixing

Answer 2

The simplest solution, I think, is to enclose your code in a repeat loop, and let the repeat loop handle all of the 'return to list' actions. Then you can delete all the duplicate choose from list lines, and all you need to do is call exit repeat when you want to get out.
--DIVE FORMULAS--
--RUN FORMULA LIST--
repeat
set x to item 1 of (choose from list {"Divers consumption at depth", "Free Gas Volume (FGV)", "Cylinder Duration", "Partial Pressure", "Initial Depth", "Cylinder Mixing"})
--DIVERS CONSUMPTION AT DEPTH--
if x is "Divers consumption at depth" then
--VARIABLES--
display dialog "What is divers breathing volume (L/min) (default 35 l/min?" default answer "35"
set varDvol to text returned of result
display dialog "What is divers absolute depth pressure (bar)" default answer ""
set varPbar to text returned of result
--FORMULA--
set answer to varDvol * varPbar
--ANSWER--
display dialog "A diver breathing " & varDvol & " l/min, at an absolute pressure of " & varPbar & " bar, will have a consumption of " & answer & " l/min" as text buttons {"See formula", "Return to formula list", "Exit"}
set response to button returned of result
--SEE FORMULA--
if response = "See formula" then
display dialog "Divers Consumption = Divers Breathing Volume * Absolute pressure of depth (bar)" buttons ("Return to Formula List")
else if response = "Exit" then
display dialog "Are you sure you wish to exit?" buttons {"Return to Formula List", "Exit"}
set response to button returned of result
if response = "exit" then
exit repeat
end if
end if
--FREE GAS VOLUME--
else if x is "Free gas volume (FGV)" then
--VARIABLES--
display dialog "What is the floodable volume of the cylinder (L)?" default answer ""
set varFvol to text returned of result
display dialog "What is the pressure of the cylinder (bar)?" default answer ""
set varCylPress to text returned of result
--FORMULA--
set answer to varFvol * varCylPress
--ANSWER--
display dialog "The free gas volume is (L)" & answer as text buttons {"See formula", "Return to formula list", "Exit"}
--OPTIONS--
set response to button returned of result
--SEE FORMULA--
if response = "See formula" then
display dialog "FGV = Floodable volume of cylinder * Pressure of cylinder (bar)"
--EXIT APP--
else if response = "Exit" then
#do a third thing
end if
end if
end repeat
You don't need to explicitly call 'quit' unless your app is designed as a stay-open app. Once you exit the repeat loop and hit the last line of code, the app will automatically terminate.

Answer 3

This should work for you…
Anywhere in your code you see this...
if response = "Return to Formula List" then
set x to item 1 of (choose from list {"Divers consumption at depth", "Free gas volume (FGV)", "Cylinder Duration", "Prartial Pressure", "Initial Depth", "Cylinder Mixing"})
end if
Try replacing it with this...
if response = "Return to Formula List" then
run me
end if