Using nested map - collections

Question

Hey I am working with nested maps as I was trying to use nested map I initialized this map>>. I need to pass accounts industry at key and need to show number of account and accounts group by industry
I have tried to put value but it is showing null pointer exception
Apex class
public class Map_Practice_Show_Account_industry {
public static void mapindustry(){
Map<String,Map<Integer,List<Account>>> m = new Map<String,Map<Integer,List<Account>>>();
List<Account> lstacc = [SELECT Id, Name, Industry FROM Account WHERE industry != Null ];
for(Account acc : lstacc){
List<Account> lstacc1 = new List<Account>();
lstacc1.add(acc);
if(m.containsKey(acc.Industry)){
m.get(acc.Industry).put(m.get(acc.Industry).size(),lstacc1);
} else {
Map<Integer, List<Account>> macc=new Map<Integer, List<Account>>();
macc.put(m.get(acc.Industry).size(),new List<Account>{acc});
m.put(acc.Industry, macc);
}
}
System.debug('#### : '+ m.get('Agriculture'));
}
}
I need to show result like agriculture as a key and at integer 2 and its accounts name

Answer 1

Your error is in second line of you else part (follow pointer for error)
public class Map_Practice_Show_Account_industry {
public static void mapindustry(){
Map<String,Map<Integer,List<Account>>> m = new Map<String,Map<Integer,List<Account>>>();
List<Account> lstacc = [SELECT Id, Name, Industry FROM Account WHERE industry != Null ];
for(Account acc : lstacc){
List<Account> lstacc1 = new List<Account>();
lstacc1.add(acc);
if(m.containsKey(acc.Industry)){
m.get(acc.Industry).put(m.get(acc.Industry).size(),lstacc1);
} else {
Map<Integer, List<Account>> macc=new Map<Integer, List<Account>>();
-->macc.put(m.get(acc.Industry).size(),new List<Account>{acc});
m.put(acc.Industry, macc);
}
}
System.debug('#### : '+ m.get('Agriculture'));
}
}
In if part you are checking if your map contains key acc.Industry but in else part you are still trying to access it even when it's not present in map, it is returning null as a result. Calling size() method on a null object will lead to Null Pointer exception.
Edit:-
then what would be the solution to get the desire result as i am not
able to get size of no of account
I think you have unnecessarily complicated this code. From what I understand from your problem statement, you only need a Map<String, List<Account>> with industry as key and related list of accounts as value. You can get size of accounts for particular industry by fetching list of accounts for that industry and then calling size method on that list. Here is code for this scenario
public class AccountUtils {
//Get all accounts with Industry as key and List of Accounts as Value
public static Map<String,List<Account>> getAccountsGroupedByIndustryMap(){
Map<String,List<Account>> accountsGroupedByIndustry = new Map<String,List<Account>>();
//Fetch all accounts with Industry
List<Account> accountsWithIndustry = [SELECT Id, Name, Industry FROM Account WHERE Industry <> NULL];
for(Account acc : accountsWithIndustry){
List<Account> accountList;
//Check if map already contains current Industry as key
if(accountsGroupedByIndustry.containsKey(acc.Industry)){
//Fetch existing list, add new value and put it back in map
accountList = accountsGroupedByIndustry.get(acc.Industry);
accountList.add(acc);
} else {//If key doesn't exist, create a new list and add account value
accountList = new List<Account>();
accountList.add(acc);
}
//Finally put this list in the map with Industry as key
accountsGroupedByIndustry.put(acc.Industry,accountList);
}
return accountsGroupedByIndustry;
}
}

Answer 2

Posting this from my cellphone not sure how formatting will look like if someone can edit :)
Like pointed above your error is in your second line of the else statement. You are trying to get the size that the industry key is pointing at BEFORE the industry type is inserted to map. Getting non existing keys returns a null and you're trying to get the size() of the null.
So to anwer you're question: Just hardcode the key as ZERO since it's the first elemnent.
Before
macc.put(m.get(acc.Industry).size(),new List<Account>{acc});
After
macc.put(0,new List<Account>{acc});