How to make a 3D text in QML - qt

Question

Using Qt Creator 4.9.1 (based on Qt 5.12.3), I'm trying to make a simple text in 3D like "Hello 3D" by a QML project.
I've searched much but unfortunately have not found a simple example for this purpose. Docs suck in this case too.
This is the code I use for that text:
import QtQuick 2.12
import QtQuick.Window 2.12
import Qt3D.Extras 2.12
Window {
visible: true
width: 640
height: 480
ExtrudedTextMesh {
depth: 2.5
font.family: "Helvetica"
text: "Hello 3D"
}
}
The issue is that no text is shown on the application's window!
Is there a way to fix this please?

Answer 1

A simple way would be to use a Texture with sourceItem set. This will allow you to use any 2D rendering you wish such as Rectangle with a centered Text:
Texture {
sourceItem: Rectangle {
width: 150
height: 150
color: Qt.rgba(0.2, 0.4, 0.7, 0.75)
Text {
anchors.centerIn: parent
text: "Hello 3D"
color: "white"
font.pointSize: 12
}
}
}
In the following example, I render the above Texture onto a spinning 3D cube:
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import QtQuick3D
Page {
anchors.fill: parent
background: Rectangle { color: "#848895" }
Node {
id: standAloneScene
DirectionalLight { ambientColor: Qt.rgba(1.0, 1.0, 1.0, 1.0) }
Node {
id: node
Model {
id: model
source: "#Cube"
materials: [
DefaultMaterial {
diffuseMap: Texture {
sourceItem: Rectangle {
width: 150
height: 150
color: Qt.rgba(0.2, 0.4, 0.7, 0.75)
Text {
anchors.centerIn: parent
text: "Hello 3D"
color: "white"
font.pointSize: 12
}
}
}
}
]
}
}
OrthographicCamera {
id: cameraOrthographicFront
y: 800; z: 1000
Component.onCompleted: lookAt(node)
}
}
View3D {
anchors.fill: parent
importScene: standAloneScene
camera: cameraOrthographicFront
}
NumberAnimation {
target: model
property: "eulerRotation.y"
loops: Animation.Infinite
running: true
from: 720; to: 0
duration: 10000
}
}
You can Try it Online!