I would like to execute the following procedure using TOAD. I would like the results of the procedure call to be output into a grid within the TOAD UI. The procedure itself is inside a package named MyPackage. The package creates a type called ct.
Type:
TYPE ct IS REF CURSOR;
Procedure Code:
PROCEDURE GetFailedTransactions (p_fails OUT ct)
IS
BEGIN
OPEN p_fails FOR SELECT *
FROM MDC_FAILURE
WHERE SUCCESS_DT IS NULL;
END;
The :my_out_cursor will prompt for the variables dialog box. Set the type of the variable to cursor and the direction to OUT. Then the output will appear in the grid section.
BEGIN
MyPackage.GetFailedTransactions(:my_out_cursor);
END;
Related
I want to create a procedure without parameters (In SQL DEVELOPER) but I am not sure how to do it, I have tried it in the following way and it sends me an error in "Num1 NUMBER";
create or replace package PK_MAC as
PROCEDURE PR_PRUEBAS
IS
Num1 NUMBER;
BEGIN
Num1 := 2;
end;
end;
You're trying to create a procedure or a package, with a procedure?
Here is a working example of what you're doing, as a package.
Your package will have two parts, a SPEC and a BODY.
The SPEC will publicly share the definition of the procedure and the variable, NUM1.
The BODY will define what the procedure actually does. Since NUM1 is defined already in the context of the package in the spec, I can use it in my procedure in the body.
create or replace package PK_MAC as
num1 integer;
PROCEDURE PR_PRUEBAS;
end;
/
create or replace package body PK_MAC IS
procedure pr_pruebas is
BEGIN
Num1 := 2;
end pr_pruebas;
end PK_MAC;
/
I am trying to run a PL/SQL package which contains a procedure with cursor (with parameter) and also procedure with 3 parameters will it work fine in hplsql.
Something like:
create package name as
procedure proc( with 3 input parameters )
end package;
create or replace package body as
variables declaration like variable -schema name .table name %type
cursor cursor name(4 parameters)
select variables
from
columns
procedure proc(parameters)
open cursor
fetch into
close
end proc
end package
Can we use a cursor declared in one procedure of the package in another procedure of the same package?
No, like anything declared inside a procedure it is local to that procedure. However you can declare a cursor at the package level and use it in both procedures.
package body my_pkg is
cursor emp_cur is select * from emp;
procedure p1 is
begin
open emp_cur;
...
close emp_cur;
end p1;
procedure p2 is
begin
open emp_cur;
...
close emp_cur;
end p2;
end;
Note though that if procedure p1 opens emp_cur but doesn't close it, then if p2 tries to open it it will get an exception.
Let's say I have a package spec. that stores constant values, which are extensively used in other packages (their procedures mainly) - so stuff like custom error messages, specific values, even lists like
TYPE myTableType IS TABLE OF VARCHAR2(100);
myObj mytype := NEW myTableType ('value1','value2')
I'd however now like to add a whole "dictionary" structure to it now - so a list of key-> value pairs in that package.
Seems I cannot initialise a table of records in that section, as already asked here:
https://asktom.oracle.com/pls/asktom/f?p=100:11%3A0%3A%3A%3A%3AP11_QUESTION_ID:14334298866128
and it seems a table of objects mentioned in the link is not a solution for me either. Not sure what would be a best workaround of some sort.
Any ideas ?
Given a package specification
CREATE OR REPLACE PACKAGE example IS
TYPE assoc_array_type IS TABLE OF VARCHAR2(100) INDEX BY VARCHAR2(100);
g_const_array assoc_array_type;
PROCEDURE dummy_proc (i_var NUMBER);
END example;
/
You can initialize the associate array of constants as follows
CREATE OR REPLACE PACKAGE BODY example IS
PROCEDURE dummy_proc (i_var NUMBER) IS
BEGIN
dbms_output.put_line(g_const_array('key_1'));
END dummy_proc;
BEGIN
g_const_array('key_1') := 'value_1';
g_const_array('key_2') := 'value_2';
g_const_array('key_3') := 'value_3';
END example;
/
To test, compile spec and body and then call dummy_proc, which will print value_1 to the console. Associative arrays can also be indexed by binary_integer or pls_integer for different needs.
EDIT: This second package shows that you can reference the public array and get the values from initialization in other packages.
CREATE OR REPLACE PACKAGE example_2 IS
PROCEDURE dummy_proc (i_key VARCHAR2);
END example_2;
/
CREATE OR REPLACE PACKAGE BODY example_2 IS
PROCEDURE dummy_proc (i_key VARCHAR2) IS
BEGIN
dbms_output.put_line(example.g_const_array(i_key));
END dummy_proc;
END example_2;
/
BEGIN
example_2.dummy_proc('key_1');
END;
/
I've to work on some older EDW scripts, which I think are in PL/SQL and queries fech data from Oracle table as well. But there is some problem with them, the part which declares variables, as shown in the image gives error. I'm unable to understand why?
Below is some part of script,
VARIABLE begin_exp_date varchar2(8)
VARIABLE end_exp_date varchar2(8)
VARIABLE begin_cal_key number
Declare
begin
:begin_exp_date := 'begin_exp_date';
:end_exp_date := 'end_exp_date';
:begin_cal_key := 'begin_cal_key';
end;
These lines produce error ORA-00900: Invalid SQL statement.
Any help?
If you plug the script in SQL*Plus, it will be executed without the ORA-00900 error. I guess you received the error when it was run in Toad.
If it is indeed PL/SQL, it should be more like this
DECLARE
begin_exp_date varchar2(8);
end_exp_date varchar2(8);
begin_cal_key number;
BEGIN
begin_exp_date := 'begin_exp_date';
-- and so on
END;
You can set constant values to the variables in the DECLARE section if you want. Note that you've defined begin_cal_key as a NUMBER so cannot assign the string 'begin_cal_key'