Arrays of Keys and Values from Request.Form in ASP Classic - asp-classic

Question

I'm trying to get an array of keys from Request.Form in ASP Classic. Theoretically I should simply be able to use Request.Form.Keys and Request.Form.Items, but they simply don't work. I get:
Object doesn't support this property or method: 'request.form.Keys'
I've tried making functions of my own, but they ultimately fail on the same point -- .Keys fails when running it on a Request.Form dictionary.
What the heck am I doing wrong????
Function dictionary_keys( dict )
Dim i
ReDim theKeys( dict.Count-1 )
for i = 0 To dict.Count-1
theKeys(i) = dict.Keys(i)
next
dictionary_keys = theKeys
End Function
Function dictionary_values( dict )
Dim i
ReDim theVals( dict.Count-1 )
for i = 0 To dict.Count-1
theVals(i) = dict.Keys(i)
next
dictionary_values = theVals
End Function
^^ Both of those fail at dict.Keys(i)
UPDATE: Based on #Lankymart's answer below, this is what I came up with:
Function request_keys( req )
Dim key, result, i
i = 0
ReDim result( req.Count-1 )
For Each key in req
result(i) = key
i = i + 1
Next
request_keys = result
End Function
Function request_values( req )
Dim key, result, i
i = 0
ReDim result( req.Count-1 )
For Each key in req
result(i) = req(key)
i = i + 1
Next
request_values = result
End Function

Answer 1

The Request.Form and Request.QueryString collections are not Scripting.Dictionary objects and as such don't support the Keys collection, but it's simple enough to convert them to a Scripting.Dictionary.
Dim dict: Set dict = Server.CreateObject("Scripting.Dictionary")
Dim key
For Each key in Request.Form
Call dict.Add(key, Request.Form(key))
Next