MPU9250 getting stuck in reset loop with ESP8266 using WOM - arduino

Question

I've been experimenting with the sleep options of both the ESP8266 wifi chip and the MPU9250 IMU. The ESP has a deep sleep command which essentially shuts the chip down apart from the real time clock until the RESET pin is pulled low, either by the ESPs GPIO16 or by an external interrupt.
The MPU9250 provides this interrupt in the form of its WOM (Wake On Motion) function, which brings the chip to bare minimum functionality until it detects motion on the built-in accelerometer, at which point its INT pin gets pulled high (I attached this pin to the gate of an NMOS transistor between the RESET pin of the ESP and GND to invert the interrupt).
When I set it up and use the following code, however, the setup enters a reset loop; both print statements execute, but I am unsure if the ESP actually has time to execute the DeepSleep command because it instantly resets as soon as the "Got here" prints and doesn't wait for motion.
However, if I disconnect and reconnect the INT connection from the NMOS while the program is running, it works temporarily and sleeps until it detects motion, at which point the reset loop begins again (even if the MPU9250 is kept completely still after moving). This means the WOM functionality is working, but something is causing the INT pin to ping high when it shouldn't be, and I can't figure out what the problem is. Does anyone know what the problem could be? Is it something I can fix with code alone?
Main code (loop() is empty):
#include <quaternionFilters.h>
#include <MPU9250.h>
#include <ESP8266WiFi.h>
extern "C" {
#include "gpio.h"
}
extern "C" {
#include "user_interface.h"
}
MPU9250 myIMU;
void setup()
{
Wire.begin(5, 14);
Serial.begin(74880);
printf("WAKE ME UP INSIDE");
delay(500);
sensorMpu9250WomEnable();
printf("Got Here");
ESP.deepSleep(0, WAKE_RF_DEFAULT);
}
In a separate file:
bool sensorMpu9250WomEnable(void)
{
uint8_t val;
// Clear registers
val = 0x80;
myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_1, val);
delay(10);
// Enable accelerometer, disable gyro
val = 0x07;
myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_2, val);
delay(10);
// Set Accel LPF setting to 184 Hz Bandwidth
val = 0x01;
myIMU.writeByte(MPU9250_ADDRESS, ACCEL_CONFIG2, val);
delay(10);
// Enable Motion Interrupt
val = 0x40;
myIMU.writeByte(MPU9250_ADDRESS, INT_ENABLE, val);
delay(10);
// Enable Accel Hardware Intelligence
val = 0xC0;
myIMU.writeByte(MPU9250_ADDRESS, MOT_DETECT_CTRL, val);
delay(10);
// Set Motion Threshold
val = 0x40;
myIMU.writeByte(MPU9250_ADDRESS, WOM_THR, val);
delay(10);
// Set Frequency of Wake-up
val = 6;
myIMU.writeByte(MPU9250_ADDRESS, LP_ACCEL_ODR, val);
delay(10);
// Enable Cycle Mode (Accel Low Power Mode)
val = 0x20;
myIMU.writeByte(MPU9250_ADDRESS, PWR_MGMT_1, val);
delay(10);
return true;
}

Answer 1

Thank you very much for this snippets, they helped me to get my project up and running.
I could fix the issue by adding a delay before start the deep sleep:
Wire.begin(I2C_SDA, I2C_SCL);
Serial.begin(115200);
Serial.println("WAKE ME UP INSIDE");
delay(500);
sensorMpu9250WomEnable();
Serial.println("Got Here");
Serial.flush();
delay(1000);
esp_sleep_enable_ext0_wakeup(GPIO_NUM_27, 1);
esp_deep_sleep_start();
Hope that helps you too.