storing several matrices on one object - julia

Question

I have this simple econometrics/statistics exercise that I'm trying to implement in Julia. I've never used Julia before, and I have already done this code in R, but I cant seem to translate the code.
Here is the outline: I have an inner loop where for a fixed N, I draw K samples from a distribution, and I store them in a matrix that is N x K. I do this for two matrices, them multiply each column of each matrix (obtaining a 2x1 vector) them and store in a 2 x K matrix.
After that, I do an outer loop for, say, 5 different values of N. In the end, I would like to have 5 different matrices that are 2 x K, so that I can plot them. What I can't figure out is how to store efficiently this matrix. In R, I would simply put them in a list, and call them each out for calculations.
using Distributions
using StatsBase
J = 500
N = [10 100 500 1000 10000]
i = 1
b = ones(3,J)
for n in N
x = ones(n,J)
e = ones(n,J)
y = ones(n,J)
for j = 1:J
x[:,j] = rand(Normal(3,1),n)
y[:,j] = 3 + 2.5*x[:,j] + e[:,j]
x = [y[:,j] x[:,j]]
b[:,j] = inv(y'*x)*(x'*y[:,j])
end
i = i + 1
i
end
I've tried with this code, but it doesn't seem to work at all. I can't even make this simple for loop below work:
for i = 1:10
x = ones(i, 10)
end
I get a ERROR: UndefVarError: x not defined. Can you guys help me?

Answer 1

You'd simply put them in a Vector{Matrix}, a vector of matrices.
But a common paradigm in Julia would be to instead define a function fthat does what you want, and then broadcast that function over N, i.e. by calling a = f.(N) (N should be a Vector, not a Matrix, BTW, so commas between the numbers rather than spaces).
So, say you want to store 5 Matrices that are 2 x K with varying K. There are in fact numerous ways you can do that, depending on taste, style, convenience, etc. Here are some examples, where k varies from 20 to 24:
# a python-style list comprehension
mymatrices = [randn(K,2) for K in 20:24]
# a function broadcast over the array
f(k) = randn(k,2)
mymatrices = f.(20:24)
# a Vector with preallocated elements
mymatrices = Vector{Matrix{Float64}}(5)
for (i, k) in enumerate(20:24) #enumerate is smart
mymatrices[i] = randn(k, 2)
end
# a Vector that grows dynamically
mymatrices = Matrix{Float64}[] # shorter optional syntax for an empty vector
for (i, k) in enumerate(20:24)
push!(mymatrices, randn(k, 2))
end
# map with an anonymous function
mymatrices = map(k -> randn(k,2), 20:24)

Answer 2

So after help from you guys and some more googleing, i've come up with this code that works. Not sure if this violates the purpose of StackOverflow, but I'm posting my answer. If you guys have time, please criticize, it seems a little too verbose, I'm sure there is a more efficient way to do this.
using Distributions
N = [10, 100, 500, 1000, 10000]
J = 500
bet = Vector{Matrix{Float64}}()
for n in N
b = Array{Float64, 2}(3, J)
for j = 1:J
x1 = Array{Float64, 2}(n,J)
x2 = Array{Float64, 2}(n,J)
epsilon = Array{Float64, 2}(n,J)
y = Array{Float64, 2}(n,J)
cons = ones(n)
x1[:,j] = rand(Normal(3,1),n)
x2[:,j] = rand(Normal(-1,1),n)
epsilon[:,j] = rand(Normal(0,1),n)
y[:,j] = 3 + 2.5*x1[:,j] + 4*x2[:,j] + epsilon[:,j]
x = [cons x1[:,j] x2[:,j]]
b[:,j] = inv(x'*x)*(x'*y[:,j])
end
push!(bet, b)
end

Answer 3

The loop works fine, and x is set correctly inside, but x is out of scope once the loop ends, and so is undefined.
julia> for i = 1:10
x = ones(i, 10)
end
julia> x
ERROR: UndefVarError: x not defined
If you create it first:
julia> x = Array{Float64}(10, 10);
julia> for i = 1:10
x = ones(i, 10)
end
julia> x
10×10 Array{Float64,2}:
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0 1.0
then it stays in scope.