what situation we can go for pragma_exception_init - oracle11g

Question

Can anybody explain why we need pragma exception init. we have user defined exception which does the same job as pragma. Your answer will be appreciated.

Answer 1

pragma exception_init is used to provide a name to an exception so that you can reference the exception by that name in the exception handler. Only a few of the several thousand Oracle exceptions have predefined names. You can use exception_init to create names for these other exceptions.
see https://docs.oracle.com/cd/B19306_01/appdev.102/b14261/errors.htm#BABGIIBI
I am editing my previous answer because I can insert formatted text here.
In your example, you are defining an exception that you are throwing, but what if you want to catch an existing exception that the system is throwing, but is unnamed? In the example that follows, I handle two specific errors 'DATA_NOT_FOUND', and ORA-600, which is a system error (and yes, I have some code that gets these).
CREATE OR REPLACE PROCEDURE exception_init_demo
AS
l_routine VARCHAR2 (30) := $$plsql_unit;
severe_system_error EXCEPTION;
PRAGMA EXCEPTION_INIT (severe_system_error, -600);
BEGIN
-- Execution code goes here
NULL;
EXCEPTION
WHEN severe_system_error
THEN
-- Severe error, log it, notify the dba, re-raise the exception
log_error (
p_application => $$plsql_unit
, p_routine => l_routine
, p_message => SQLERRM || UTL_TCP.crlf || DBMS_UTILITY.format_error_backtrace ()
);
notify_dba;
RAISE;
WHEN NO_DATA_FOUND
THEN
-- No data was found, this is OK, ignore error and return
return;
WHEN OTHERS
THEN
-- all other errors we will log and re-raise
log_error (
p_application => $$plsql_unit
, p_routine => l_routine
, p_message => SQLERRM || UTL_TCP.crlf || DBMS_UTILITY.format_error_backtrace ()
);
RAISE;
END;