Not able to display average - plsql

Question

i want to display an average score but its not getting displayed even though the code is executed, here is my code:
set serveroutput on size 10000;
declare
s_student_id grade.student_id%type;
g_score grade.score%type;
begin
for c in (select distinct grade.student_id, avg(grade.score) into s_student_id, g_score from grade inner join class on grade.class_id = class.class_id group by grade.student_id having count(class.course_id) > 4)
loop
dbms_output.put_line('Student' || c.student_id || ' :' || g_score);
end loop;
exception
when no_data_found then dbms_output.put_line('There are no students who selected more than 4 courses');
end;
/
Output:
anonymous block completed
Student1 :

Answer 1

I think this is what you're after:
set serveroutput on size 10000;
declare
v_counter integer := 0;
begin
for rec in (select grade.student_id,
avg(grade.score) g_score
from grade
inner join class on grade.class_id = class.class_id
group by grade.student_id
having count(class.course_id) > 4)
loop
v_counter := v_counter + 1;
dbms_output.put_line('Student: ' || rec.student_id || ', avg score: ' || rec.g_score);
end loop;
if v_counter = 0 then
raise no_data_found;
end if;
exception
when no_data_found then
dbms_output.put_line('There are no students who selected more than 4 courses');
end;
/
There are several points to note:
Good formatting of your sql statements (and pl/sql) will aid you when it comes to understanding, debugging and maintaining your code. If you can read it easily, chances are you'll understand it more quickly.
If you're using a cursor-for-loop, you don't need the into clause - that's only for when you are using an explicit select statement. You also don't need to declare your own variables to hold the data returned by the cursor - the cursor-for-loop declares the record variable to return the row into for you - in your example, that would be c, which I've renamed to rec for clarity.
Giving identifiers names that reflect what they are/do is also essential for ease of maintenance, readability etc.
When referring to the contents of the field from the cursor, use the record variable, e.g. rec.student_id, rec.g_score. Thus, it is important to give your columns aliases if you're doing anything other than a straight select (e.g. I've given avg(grade.score) an alias, but I didn't need to bother for grade.student_id)
If there are no records returned by the cursor, you will never get a no_data_found exception. Instead, you'll have to check to see if you had any rows returned - the easiest way to do this is to have some sort of counter. Once the loop has completed, you can then check the counter. If it shows that no rows were returned, you can then raise the no_data_found error yourself - or, more simply, you could skip the exception block and just put the dbms_output statement there instead. YMMV.
If you are going to go with the exception block, in production code you would most likely want to raise an actual error. In that case you would use RAISE or, if you need to pass a user defined error message out, RAISE_APPLICATION_ERROR.
Finally, I'm guessing this is some sort of homework question, and as such, the presence of the dbms_output statements is ok. However, out in the real world, you only ever want to use dbms_output for ad-hoc debugging or in non-production code because relying on dbms_output to pass information around to calling code is just asking for trouble. It's not robust, and there are far better, reliable methods of passing data around.