as400 CL script arithmetic gives 0 - math

Question

I'm trying to calculate the remainder of a division with the algorithm:
remainder = dividend - (dividend / divisor) * divisor
All calculated in integers.
Example:
Get the remainder of 15 / 6.
1. (15 / 6) = 2
2. (2) * 6 = 12
3. 15 - 12 = 3
The remainder of 15/6 is indeed 3.
My problem is using this algorithm in my CL script simply returns 0 all the time. Why is that?
pgm
dcl var(&dividend) type(*int) value(15)
dcl var(&divisor) type(*int) value(6)
dcl var(&remainder) type(*int)
dcl var(&msg) type(*char)
/* Calculate remainder. [ed: 29Sep2016] "* &remainder" is now: "* &divisor" */
chgvar var(&remainder) value(&dividend - (&dividend / &divisor) * &divisor)
/* Prior to 29-Sep-2016 redaction, the above was coded as the incorrect expression: +
chgvar var(&remainder) value(&dividend - (&dividend / &divisor) * &remainder) +
and remains, commented-out, to preserve relevance of user-comments about the OP */
/* Cast remainder and display. */
chgvar var(&msg) value(&remainder)
sndpgmmsg msg(&msg)
endpgm
Compiled with:
crtclpgm pgm(test) srcfile(test) srcmbr(test)
Run:
call test
Output:
0

Answer 1

This is quite interesting system behaviour. It would seem that the engine doesn't apply the integer trunking on the values in the brackets before multiplying it. So in other words the following is happening:
&dividend - (&dividend / &divisor) * &divisor
= 15 - (15 / 6) * 6
= 15 - 2.5 * 6
= 15 - 15
= 0
To fix it I did the following:
chgvar var(&remainder) value(&dividend / &divisor)
chgvar var(&remainder) value(&dividend - &remainder * &divisor)

Answer 2

The described result is a side effect of the / that was coded as the division operator. The / operator is not an integer division operator in the CL; some languages might offer the // as an additional division operator for that effect, or perhaps as a scalar function such as a DIV; though when a language offers such additional arithmetic features, they are likely also to offer a related scalar such as MOD or REM to directly obtain a remainder.
The IRP listing revealed the CL operated as if explicitly coded as having an intermediate value with non-zero scale; effectively TYPE(*DEC) LEN(24 9), but the CL only allow 15 digits of precision, so I use TYPE(*DEC) LEN(15 5) in this example of a program that mimics the creation of the intermediate result for the division before performing the rest of the expression:
pgm
dcl var(&dividend) type(*int) value(15)
dcl var(&divisor) type(*int) value(6)
dcl var(&remainder) type(*int)
dcl var(&intermedP) type(*dec) len(15 5)
/* Calculate remainder. *two-step process -- mimics IRP listing; yields 0 */
chgvar var(&intermedP) value(&dividend / &divisor) /* P15,5 intermed result */
chgvar var(&remainder) value(&dividend - &intermedP * &divisor )
Because the proper result requires that the (&dividend / &divisor) [as part of the expression &dividend - (&dividend / &divisor) * &divisor] must yield an integer result, that means the intermediate result for that division operation must be forced to either the *INT type or to another numeric type with zero-scale.
And as the already-accepted answer shows, the following revision to use an integer for the intermediate result resolves the issue:
pgm
dcl var(&dividend) type(*int) value(15)
dcl var(&divisor) type(*int) value(6)
dcl var(&remainder) type(*int)
dcl var(&intermedI) type(*int)
/* Calculate remainder. *two-step process; per change, correctly yields 3 */
chgvar var(&intermedI) value(&dividend / &divisor) /* *INT intermed result */
chgvar var(&remainder) value(&dividend - &intermedI * &divisor )
Unlike what I alluded in a 24Sep comment to the OP, there is no ability to code the following expression to achieve the desired result in just one CHGVAR statement; the first expression fails syntax checking with msg CPD0058 "Built-in function %INT allows 1 arguments." and the second fails with msg CPD0181 "Argument for built-in function %INT not valid.". And I would expect the same effect [but I did not verify] from coding the %DEC builtin [with specification of a zero-scale; i.e. zero specified for the decimal-places argument]:
( &dividend - %int(&dividend / &divisor) * &divisor )
( &dividend - %int((&dividend / &divisor)) * &divisor )