How would you model this non-relational database? - graph

Question

I am making a graph database using Neo4j and I'm wondering what's the best way to model this case:
Person1 > told > quote > to > Person2 > who told it to -> Person3 -> who told it to -> Person4 > Who told it to -> Person1
I've thought about quote being an attribute of link. But then maybe quote needs also to be a node. In this case the edges would be "told" and "was_told". Like:
Person1 -> created > quote
Quote attributes: id, text
Person attributes: id, name
Person2 > told: {to: Person 3} > quote
Person3 > was_told: {by: Person2} > quote
or:
Person3 > told:quote > Person1
What's the best approach to use to model this database?

Answer 1

I think you need the following model:
A fragment (talk) of a conversation (including time)
Who was the speaker of this fragment
Who was an audience of this fragment
Content (quote) of this fragment
For example, here's the code for creating the first fragment:
MERGE (P1:Person {name:'Person1'})
MERGE (P2:Person {name:'Person2'})
MERGE (Q:Quote {name:'Quote1', text:'Quote1 text'})
MERGE (P1)<-[:has_speaker]-(T1:Talk {name:'Talk1', time: 1})-[:has_audience]->(P2)
MERGE (T1)-[:talk_about]->(Q)
Visualization:
The query for the entire life cycle of a quote:
MATCH (Q:Quote {name:'Quote1', text:'Quote1 text'})<-[:talk_about]-(T:Talk)
WITH Q, T
MATCH (P1:Person)<-[:has_speaker]-(T)-[:has_audience]->(P2)
WITH Q, T, P1 as speaker, collect(P2.name) as audience ORDER BY T.time ASC
RETURN Q as quote,
collect( {time: T.time,
speaker: speaker.name,
audience: audience}
) as quoteTimeline