XQuery: debugging recursive function - xquery

Question

xqy file:
import module namespace functx="http://www.functx.com";
declare variable $defaultXMLNS:="http://www.test.com#";
declare variable $defaultXMLBase:=$defaultXMLNS;
declare function local:descriptionConstructorTail(
$seq as item()*,
$i as xs:integer?,
$res as item()*
)
{
if($i <= 0)
then $res
else local:descriptionConstructorTail($seq,
$i - 1,
functx:value-union($res,
(<test1 about="{$seq[$i]/#value}"/>)))
};
declare function local:descriptionConstructor($pnode as node()*)
{
local:descriptionConstructorTail($pnode//xs:enumeration,
count($pnode//xs:enumeration),
())
};
element test
{
local:descriptionConstructor(doc("./test2.xsd"))
}
xsd file:
<?xml version="1.0"?>
<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema"
attributeFormDefault="unqualified"
elementFormDefault="qualified">
<xs:simpleType name="size">
<xs:restriction base="xs:string">
<xs:enumeration value="small" />
<xs:enumeration value="medium" />
<xs:enumeration value="large" />
</xs:restriction>
</xs:simpleType>
</xs:schema>
I have been messing around with this small program for 2 hours. The output is always not expected.
$ basex test2.xqy
<test/>
For the example xsd file above, I want to have output like this:
<test>
<test1 about="small"/>
<test1 about="medium"/>
<test1 about="large"/>
</test>
This example may not seen logical, because you don't have to use recursive function to do this. But I wanna do this as an exercise for recursive function.

Answer 1

While the functx library is a very convenient collection of utility functions, is it important to know what exactly those do so you can avoid surprises like this one. functx:value-union(...) is implemented as follows:
declare function functx:value-union(
$arg1 as xs:anyAtomicType*,
$arg2 as xs:anyAtomicType*
) as xs:anyAtomicType* {
distinct-values(($arg1, $arg2))
};
So it just applies distinct-values(...) to the concatenation of its inputs. Since this function works on values of typexs:anyAtomicType, your XML nodes are atomized. This only leaves their text contents, which your elements don't have. So you just build the union of empty sequences over and over.
This should work fine:
declare function local:descriptionConstructorTail($seq as item()*, $i as xs:integer?, $res as item()*) {
if($i <= 0) then $res
else local:descriptionConstructorTail($seq, $i - 1, distinct-values(($res, $seq[$i]/#value)))
};
declare function local:descriptionConstructor($pnode as node()*) {
let $enums := $pnode//xs:enumeration
for $res in local:descriptionConstructorTail($enums, count($enums), ())
return <test1 about="{$res}"/>
};
element test {
local:descriptionConstructor(doc("./test2.xsd"))
}
By the way your recursive function follows the recursion scheme encoded by the higher-order function fold-right(...), so you could also write:
declare function local:descriptionConstructor($pnode as node()*) {
for $res in
fold-right(
$pnode//xs:enumeration,
(),
function($enum, $res) {
distinct-values(($enum/#value, $res))
}
)
return <test1 about="{$res}"/>
};
element test {
local:descriptionConstructor(doc("./test2.xsd"))
}