Override an ASCX control method in parent page - asp.net

Question

I have an ASCX user control that is being used in about 60 web forms pages. This control basically renders a series of nested drop down lists.
Inside the control, the method for populating the final list is like this:
Public Sub PopulateList()
Dim dt as DataTable = MyDAL.GetListValues()
For each dr as DataRow in dt.Rows
Dim li as new ListItem
' ...
myDDL.Items.Add(li)
Next
End Sub
In a small handful of pages, I need this method to work slightly differently (the list items are populated with more details, from a different table).
Is it possible somehow for the parent page of the control to somehow override the method? I read about Overriding on various MSDN pages, but can't figure this out. I can declare the method as...
Public Overridable Sub PopulateList()
... but then in VS2015, when I try to create an overriding method using Public Overrides the Intellisense menu does not contain any reference to the user control, or the method. I assume that this is because the control isn't actually being inherited by the page?
Is this possible to do, or is there another way please?

Answer 1

You cannot "override" the method in the parent page, because the page does not inherit from your control's class.
You could possibly create an event handler, or pass in a delegate to modify the behavior of the method.
For example:
Public Class Test1
Dim t2 As New Test2
Sub New()
' Call populateList with an action handler
t2.PopulateList(Sub(ddl)
' Do your logic here
Dim dt As DataTable = MyDAL.GetListValues()
For Each dr As DataRow In dt.Rows
Dim li As New ListItem
' ...
ddl.Items.Add(li)
Next
End Sub)
End Sub
End Class
Public Class Test2
Public Sub PopulateList(Optional handler As Action(Of DropDownList) = Nothing)
If handler Is Nothing Then
' Default behavior
Dim dt As DataTable = MyDAL.GetListValues()
For Each dr As DataRow In dt.Rows
Dim li As New ListItem
' ...
myDDL.Items.Add(li)
Next
Else
' Invoke action handler and pass a reference to the dropdown you want to add items to
handler(myDDL)
End If
End Sub
End Class
Example using an event:
Event MyCustomEvent As EventHandler(Of MyCustomEventArgs)
Public Sub PopulateList()
Dim args As New MyCustomEventArgs()
args.ListObject = myDDL
RaiseEvent MyCustomEvent(Me, args)
' Do default behavior if not handled by event code
If Not args.Handled Then
Dim dt As DataTable = MyDAL.GetListValues()
For Each dr As DataRow In dt.Rows
Dim li As New ListItem
' ...
myDDL.Items.Add(li)
Next
End If
End Sub
Custom event args class:
Public Class MyCustomEventArgs
Inherits EventArgs
Public Property Handled As Boolean
Public Property ListObject As DropDownList
End Class
Handled on your page:
Protected Sub MyControl_MyCustomEvent(sender As Object, e As MyCustomEventArgs) Handles MyControl.MyCustomEvent
e.Handled = True
' Do work on your list
Dim mylist = e.ListObject
End Sub