Not able to manipulate paths collection in neo4j cypher - collections

Question

Still struggling to get the query right. Following graph is mostly unidirectional and represents who likes whom. But people with "Friends" relationship are particular about with whom they are ultimate friends with.
create (jacob {short:"Jacob",level:"start"})
,(leena{short:"Leena"})
,(bob{short:"Bob",level:"end"})
,(brad{short:"Brad",level:"end"})
,(jacob)-[:LIKES]->(leena)
,(leena)-[:LIKES]->(bob)
,(leena)-[:LIKES]->(brad)
,(jacob)-[:FRIENDS]->(brad)
,(kyle{short:"Kyle",level:"start"})
,(rick{short:"Rick"})
,(kyle)-[:LIKES]->(leena)
,(kyle)-[:LIKES]->(rick)
,(rick)-[:LIKES]->(brad);
All source to end 'likes' are given by
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
return distinct extract(m in nodes(p) | m.short);
[Jacob, Leena, Bob]
[Jacob, Leena, Brad]
[Kyle, Rick, Brad]
[Kyle, Leena, Bob]
[Kyle, Leena, Brad]
But for Brad the LIKES should come from his FRIENDS. In the graph, for Brad, only Jacob is his FRIEND. So ultimate likes through Kyle should be excluded from the output.
The logic I'm trying to implement is to get unnecessary paths and exclude them from above output.
unnecessary paths given by following query. There where clause is simple because the FRIENDship is always found between 2 and then its easy to collect first and last nodes in collection.
match q=()-[:FRIENDS*1]->()
with collect(nodes(q)[0]) as y,collect(nodes(q)[1]) as z
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
where any(x in nodes(p) where x in z) and not any(x in nodes(p) where x in y)
return distinct extract(m in nodes(p) | m.short);
[Kyle, Rick, Brad]
[Kyle, Leena, Brad]
Then the exclusion
match q=()-[:FRIENDS*1]->()
with collect(nodes(q)[0]) as y,collect(nodes(q)[1]) as z
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
where any(x in nodes(p) where x in z) and not any(x in nodes(p) where x in y)
match r=({level:'start'})-[:LIKES*1..6]->({level:'end'})
where not all(node2 in nodes(p) where node2 in nodes(r))
return distinct extract(m in nodes(r) | m.short);
Still I get all paths including unnecessary ones. In cypher can complete collection be compared? In above query not all(.. is not working.
To make the graph generic, the start and end nodes can exist inbetween ie there can be nodes beyond end nodes and before start.

Answer 1

If the first query returns the complete set of LIKES paths, and the second query returns the set of LIKES paths to be excluded, does this query give you the next result you are looking for?
It collects each set in a set to keep and an irrelevant set then returns only the sets in the keep set that are not in the irrelevant set.
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
with collect(nodes(p)) as full_set
match q=()-[:FRIENDS*1]->()
with full_set, collect(nodes(q)[0]) as y,collect(nodes(q)[1]) as z
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
where any(x in nodes(p) where x in z) and not any(x in nodes(p) where x in y)
with full_set, collect(nodes(p)) as irrelevent_set
with filter (keep in full_set where not keep in irrelevent_set) as keep_sets
unwind keep_sets as keep
return extract(person in keep | person.short)
Edit to return paths instead:
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
with collect(p) as full_set
match q=()-[:FRIENDS*1]->()
with full_set, collect(nodes(q)[0]) as y,collect(nodes(q)[1]) as z
match p=({level:'start'})-[:LIKES*1..6]->({level:'end'})
where any(x in nodes(p) where x in z) and not any(x in nodes(p) where x in y)
with full_set, collect(p) as irrelevent_set
with filter (keep in full_set where not keep in irrelevent_set) as keep_sets
unwind keep_sets as keep
return keep