Merge two maps to resultant Map in Groovy - collections

Question

I have two maps as:
firstMap = [totalProjectCount:53, activeProjectCount:29, completedProjectCount:1, userCount:85]
secondMap = [totalProjectCount:48, activeProjectCount:41, completedProjectCount:0, userCount:123]
and i need result such as:
resultMap = [totalProjectCount:101, activeProjectCount:70, completedProjectCount:1, userCount:208]

Answer 1

Yet another Groovy alternative:
def firstMap = [totalProjectCount:53, activeProjectCount:29, completedProjectCount:1, userCount:85, a:1]
def secondMap = [totalProjectCount:48, activeProjectCount:41, completedProjectCount:0, userCount:123, b:2]
def result = [firstMap, secondMap]*.keySet().flatten().toSet().collectEntries { k ->
[k, (firstMap[k] ?: 0) + (secondMap[k] ?: 0)]
}
assert result == [a:1, b:2, completedProjectCount:1, userCount:208, activeProjectCount:70, totalProjectCount:101]
This also works if you have values in one map that don't exist in the other (see a and b)

Answer 2

To make this a reusable part of your toolbelt, it's important, to extract the function you want to merge with.
The merging itself is then just the creation of a new map with all the keys of the maps and the values reduced with the passed function.
Map mergeWith(Closure fn, Map... maps) {
maps*.keySet().sum().collectEntries{k->
[k, maps.findAll{it.containsKey k}*.get(k).inject(fn)]
}
}
def m1 = [a:53, b:29, c:1, x:85]
def m2 = [a:48, b:41, c:0, y:123]
def m3 = [z:42]
// sum
assert mergeWith({a,b->a+b}, m1, m2, m3)==[a:101, b:70, c:1, x:85, y:123, z:42]
// product
assert mergeWith({a,b->a*b}, m1, m2, m3)==[a:2544, b:1189, c:0, x:85, y:123, z:42]
edit: as requested in the comments, some explanations
mergeWith takes a reducing function (a function, that gets called with
two params and returns one value) and some maps. This means, you can a)
use it for other operations than just the sum and b) you can use it for
more than one map.
maps*.keySet().sum() is the union of all keys. Then we
collectEntries (build a new map) over that set of keys. For the value
find all maps, that contains the key (this makes this work nicely even
in cases, where the actual value is falsey) and fetch the values of k
via the spread operator. Then we reduce (oddly named inject) the list
of values with the passed function.

Answer 3

Map additionJoin( Map firstMap, Map secondMap )
{
def resultMap = [:];
resultMap.putAll( firstMap );
resultMap.putAll( secondMap );
resultMap.each { key, value ->
if( firstMap[key] && secondMap[key] )
{
resultMap[key] = firstMap[key] + secondMap[key]
}
}
return resultMap;
}
def firstMap = [totalProjectCount:53, activeProjectCount:29, completedProjectCount:1, userCount:85]
def secondMap = [totalProjectCount:48, activeProjectCount:41, completedProjectCount:0, userCount:123]
def resultMap = additionJoin( firstMap , secondMap )
println resultMap

Answer 4

Try this :
Map<String, Integer> resultMap = new HashMap<>(firstMap);
secondMap.forEach((k, v) -> resultMap.merge(k, v, Integer::sum));

Answer 5

More efficiently, you could write it like below:
Map additionJoin(Map firstMap, Map secondMap)
{
secondMap.each { key, value ->
if( firstMap[key])
{
firstMap[key] = firstMap[key] + secondMap[key]
}
}
return firstMap;
}
def firstMap = [totalProjectCount:53, activeProjectCount:29, completedProjectCount:1, userCount:85]
def secondMap = [totalProjectCount:48, activeProjectCount:41, completedProjectCount:0, userCount:123]
def resultMap additionJoin( firstMap , secondMap )
println resultMap
This would be high in performance as it would save using a third map.
Also, if you understand value by reference you can do it like below as well:
void additionJoin(Map firstMap, Map secondMap)
{
secondMap.each { key, value ->
if( firstMap[key])
{
firstMap[key] = firstMap[key] + secondMap[key]
}
}
}
def firstMap = [totalProjectCount:53, activeProjectCount:29, completedProjectCount:1, userCount:85]
def secondMap = [totalProjectCount:48, activeProjectCount:41, completedProjectCount:0, userCount:123]
additionJoin( firstMap , secondMap )
println firstMap
Though later solution hampers the readability (have opinionated view) which could be achieved by additional statement as below:
def resultMap = firstMap
Hope it helps you do the same efficiently.