How to reduce duplicated nodes in XQuery result? - xquery

Question

Currently, I have a problem in having duplicate nodes.
Here is the query where I suffer from duplicate node result.
for $cityA in doc("countries.xml")//city
for $cityB in doc("countries.xml")//city
where not ($cityA is $cityB) and $cityA/name = $cityB/name
return $cityA/name
and the result of my query is shown here:
<name>Hyderabad</name>
<name>Hyderabad</name>
But what I want is this:
<name>Hyderabad</name>
I understand the problem in my query, why duplicates occur. But: how can I get a result without duplicates?
The countries.xml file is available for download.

Answer 1

The problem is that you calculate the cross product, which you're then filtering. There are different ways to mitigate this. An obvious one would be to return only distinct values:
for $city in distinct-values(
for $cityA in doc("countries.xml")//city
for $cityB in doc("countries.xml")//city
where not ($cityA is $cityB) and $cityA/name = $cityB/name
return $cityA/name
)
return <name>{ $city }</name>
But this feels like a horrible hack. Better make sure that you're only returning the "first" result, which can be done using the node order operator << in a where clause:
for $cityA in doc("countries.xml")//city
for $cityB in doc("countries.xml")//city
where not ($cityA is $cityB) and $cityA/name = $cityB/name
where $cityA << $cityB
return $cityA/name
But still, this has the unnecessary explicit cross product. You can do without by changing the query:
for $city in doc("countries.xml")//city
where $city/following::city[name=$city/name]
return $city/name
This one loops over all cities, and selects whose that have another one occurring later in the document having the same value. You could even use predicates to perform the same query with plain XPath 1.0 (being a subset of XQuery) in a single line:
doc("countries.xml")//city[following::city/name=name]/name

Answer 2

In XQuery 3.0 you can use grouping
for $city in doc('countries.xml')//city
group by $name := $city/name
where count($city) ge 2
return <name>{$name}</city>