Pig Latin Recursion - recursion

Question

I'm a Pig Latin beginner and I needed to accomplish a task where I should identify troll posts. Such posts are calculated by the ratio of #likes/#replies of a post. Therefore, it is necessary to determine for each post (1) its replies and (2) recursively all the replies for each reply.
In the task it was stated that either Map Reduce, Pig Latin or Hive can be used. But since I do not know how to achieve recursion in pure Pig Latin, I solved it by using embeddedPig, where I use Java for the recursion part. So my question is: Is it possible at all to realize such a recursive task using only Pig Latin? And if so, can anyone show me any really small example applying recursion?
The Test Input is a small static social network containing users with posts, likes and so on. Every line is a triple of subject-predicate-object, e.g. Bill-likes-anyPost. Now each post can be in such a relation with a reply, and this reply can also be in a relation with a reply (meaning someone replied to the reply). My Pig Latin Code below tries to output the posts with their ratio. The problem is that I do not use recursion to get all the replies of each reply.
REGISTER RDFStorage.jar ;
indata = LOAD '$input_file' USING RDFStorage() AS
(s:chararray,p:chararray,o:chararray) ;
likes = FILTER indata BY p == 'sib:like';
likes_group = GROUP likes BY o;
likes_grouped_count = FOREACH likes_group GENERATE group AS object,
COUNT(likes) AS amount;
comments = FILTER indata BY STARTSWITH(s,'sibpo:') AND p == 'sioc:container_of';
comments_grouped = GROUP comments BY s;
comments_grouped_count = FOREACH comments_grouped GENERATE group AS subject,
COUNT(comments) AS amount;
--GET creation date for all posts
posts_dates_t = FILTER indata BY STARTSWITH(s,'sibpo:') AND p == 'dc:created';
posts_dates = FOREACH posts_dates_t GENERATE s, p, REGEX_EXTRACT(o, '\\"([0-9]{4}-[0-9]{2}-[0-9]{2})T', 1) AS o;
--Get creation date for all comments
comments_dates_t = FILTER indata BY STARTSWITH(s,'sibc:') AND p == 'dc:created';
comments_dates = FOREACH comments_dates_t GENERATE s, p, REGEX_EXTRACT(o, '\\"([0-9]{4}-[0-9]{2}-[0-9]{2})T', 1) AS o;
--Associate each comment to its corresponding post that has a creation date
posts_comments = JOIN posts_dates BY s, comments BY s;
--Join to get creation dates for all comments
posts_comments_with_dates = JOIN posts_comments BY comments::o, comments_dates BY s;
--calculate the days between a post and each one of its comments
all_dates = FOREACH posts_comments_with_dates GENERATE $0 AS post,ABS (DaysBetween(ToDate( $2 ),ToDate($8))) as lifetime_1 ;
--GROUP by post
all_dates_grouped = GROUP all_dates BY post;
--Get the life time of a post, which is the maximum difference between a post and its comments
posts_lifetime = FOREACH all_dates_grouped GENERATE group as post, MAX (all_dates.lifetime_1) as lifetime_2;
combined = JOIN likes_grouped_count BY object, comments_grouped_count BY subject;
combined_dates= JOIN combined BY comments_grouped_count::subject, posts_lifetime BY post;
combined_ratio = FOREACH combined_dates GENERATE likes_grouped_count::object AS post, (float)likes_grouped_count::amount/(float)comments_grouped_count::amount/1f AS ratio, posts_lifetime::lifetime_2 as lifetime ;
--Sort posts by ration first then by lifetime ascending
combined_ratio_sorted = ORDER combined_ratio BY ratio ASC, lifetime ASC;
outdata = LIMIT combined_ratio_sorted 50;
STORE outdata INTO '$output_file' USING PigStorage(',') ;
Thanks for reading and spending your time.