How to close SYS_REF CURSOR in oracle pl/sql? - plsql

Question

I can't compile this pl/sql. I am not familiar with pl/sql and I want to close c_cur after using it.
create or replace
procedure GET_INSPECTION_CALL_REF_NO (
in_vendor_code varchar2,
c_cur out SYS_REFCURSOR
)
is
declare
c_cur is
select call_log_id, call_log_ref_no
from INSPECTION_CALL_LOG
where modified_by = in_vendor_code;
var_c_cur c_cur%ROWTYPE;
begin
open c_cur;
loop
fetch c_cur into var_c_cur
exit when c_cur%notfound;
end loop;
close c_cur;
end;
end GET_INSPECTION_CALL_REF_NO;

Answer 1

You can rewrite your procedure like,
create or replace
procedure GET_INSPECTION_CALL_REF_NO (
in_vendor_code varchar2,
c_cur out SYS_REFCURSOR
)
as
v_call_log_id INSPECTION_CALL_LOG.call_log_id%type;
v_call_log_ref_no INSPECTION_CALL_LOG.call_log_ref_no%type;
begin
open c_cur for
select call_log_id, call_log_ref_no
from INSPECTION_CALL_LOG
where modified_by = in_vendor_code;
loop
fetch c_cur into v_call_log_id, v_call_log_ref_no;
exit when c_cur%notfound;
end loop;
close c_cur; --really needed here???
end GET_INSPECTION_CALL_REF_NO;
A REF CURSOR is a PL/SQL data type whose value is the memory address
of a query work area on the database. In essence, a REF CURSOR is a
pointer or a handle to a result set on the database
Here you are using the ref-cursor to return the result hence no point in closing the cursor.
Its the duty of the caller of this proc to close the cursor.
You cannot do var_c_cur c_cur%ROWTYPE; on ref-cursor
You have to use table.column%type or DBMS_SQL package.
This procedure can be rewritten to ,
create or replace
procedure GET_INSPECTION_CALL_REF_NO (
in_vendor_code varchar2,
c_cur out SYS_REFCURSOR
)
as
begin
open c_cur for
select call_log_id, call_log_ref_no
from INSPECTION_CALL_LOG
where modified_by = in_vendor_code;
end GET_INSPECTION_CALL_REF_NO;
Closing the Ref-Cursor;
DECLARE
v_cur SYS_REFCURSOR;
v_call_log_id INSPECTION_CALL_LOG.call_log_id%type;
v_call_log_ref_no INSPECTION_CALL_LOG.call_log_ref_no%type;
BEGIN
GET_INSPECTION_CALL_REF_NO('some_code', v_cur);
loop
fetch c_cur into v_call_log_id, v_call_log_ref_no;
exit when c_cur%notfound;
-- Use v_call_log_id, and v_call_log_ref_no...
end loop;
CLOSE v_cur; --Please note.
END;
/