Upload file via multipart request - http

Question

I need to upload a zip file to a url that accepts files passed in a multipart request. The name of the part in the "multipart/form-data" request to bind to is "archive".
What I have so far:
auto f = new BufferedFile(<path_to_file>, FileMode.In);
scope (exit) f.close();
http = HTTP(<post_url>);
http.addRequestHeader("Content-Type", "multipart/form-data;boundary=heregoes");
http.verifyPeer(false);
http.method = HTTP.Method.post;
http.onSend = (void[] data){
return f.read(cast(ubyte[]) data);
};
http.contentLength = cast(size_t) f.size;
http.setCookieJar("<cookie_file_used_for_auth>");
http.perform();
How can I set the key "archive" in the request to map the file to?
Thanks

Answer 1

I don't use std.net.curl much so I don't know if there's an easier way, but the data you're sending is just a blob on the wire, so you could set the other values manually.
Don't just send the data, put it in a MIME envelope. I wrote this little class a while ago to help form that:
/// Creates a multipart/form-data object that is suitable for file uploads and other kinds of POST
class FormData {
struct MimePart {
string name;
const(void)[] data;
string contentType;
string filename;
}
MimePart[] parts;
void append(string key, in void[] value, string contentType = null, string filename = null) {
parts ~= MimePart(key, value, contentType, filename);
}
private string boundary = "0016e64be86203dd36047610926a"; // FIXME
ubyte[] toBytes() {
string data;
foreach(part; parts) {
data ~= "--" ~ boundary ~ "\r\n";
data ~= "Content-Disposition: form-data; name=\""~part.name~"\"";
if(part.filename !is null)
data ~= "; filename=\""~part.filename~"\"";
data ~= "\r\n";
if(part.contentType !is null)
data ~= "Content-Type: " ~ part.contentType ~ "\r\n";
data ~= "\r\n";
data ~= cast(string) part.data;
data ~= "\r\n";
}
data ~= "--" ~ boundary ~ "--\r\n";
return cast(ubyte[]) data;
}
}
I know that code sucks and I haven't tested it recently but the output eyeballs to be right. It should work like this:
auto data = new FormData();
data.append("archive", "YOUR DATA", "application/octet-stream"); // or whatever mime type you need
auto bytes = data.toBytes();
Then you send bytes instead of your file contents when curl asks for it. The setPostData method of HTTP looks like a place to put it. Remember to set your content type in the set post data too to the multipart/form-data with the boundary (you can change the one in my class if you like).
http://dlang.org/phobos/std_net_curl.html#setPostData
I know the curl library has functions to do this for you too... but I don't think the high level std.net.curl interface exposes them :(