Loop based in variable value in asp classic - asp-classic

Question

I have to output a table based on value of a variable. I have a unique block of table with variables. Depending on the view there should be a loop the re-read the table.
The variable could have the values Two or Three or both. I have to output the table with view One in all the cases.
Example #1:
Views = "Two, Three"
Output:
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
Example #2:
Views = "Two"
Output:
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
Example #3:
Views = "Three"
Output:
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
Tried to mix some While and For, without success.
<%
i=2
Do While i = 0
%>
<table>
<tr>
<td><% Response.Write i %></td>
</tr>
</table>
<%
i=i-1
Loop
%>

Answer 1

Try this:
<%
Dim Views : Views ="Two" 'Change this to check
Response.write "Initial View =" & Views & "<br/>"
'But "One" will always be printed
If InStr(Views,"One")=0 Then
'add if there is no "One" already
Views = Views & ",One"
End If
Response.write "New View =" & Views & "<br/>"
Dim ArrValues : ArrValues =Array("One","Two","Three")
Dim Counter
For Counter=0 to UBound(ArrValues)
If InStr(Views,ArrValues(Counter))<>0 Then
%>
<table>
<tr>
<td>Table For View <%=ArrValues(Counter)%></td>
</tr>
</table>
<%
'Response.write ArrValues(Counter) & "<br/>"
End If
Next
%>

Answer 2

I think something like this would work fine. I just use if else if. Also I compansated for the case that Views could equal "Two, Three" or "Three, Two".
<%if Views = "Two" then%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<%else if Views = "Three"%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
<%else if Views = "Two, Three"%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
<%else if Views = "Three, Two"%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<%end if%>

Answer 3

There are multiple ways to approach this but without changing your code to much, it can be done by splitting your Views variable into an Array using the comma , as a delimiter. Once you have the Array use a For loop to iterate through the Views and use a Select statement to return the correct view.
As you specified that Table One will always be included it has been left outside of the loop.
Something like this (not tested);
<%
Dim item, items
'Build the array from the Views comma separated string
Views = Split(Views, ",")
'Always include Table One
%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<%
'Check we have an Array built from the Split().
If IsArray(Views) Then
'How many views have we requested?
items = UBound(Views)
For item = 0 To items
'What view are we current looking at in the loop?
Select Case LCase(Trim(Views(item) & ""))
Case "two"
%>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<%
Case "three"
%>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
<%
End Select
Next
End If
%>
Depending on the complexity of your views you could break each table into it's own Sub procedure or one Sub procedure and call in place of the in-line table definitions. Something like below;
Sub ShowTable(view)
'Keep all in-line table definitions together.
Select Case Trim(LCase(view & ""))
Case "one"
%>
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<%
Case "two"
%>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<%
Case "three"
%>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
<%
End Select
End Sub
In the main loop you would added ShowTable() calls in place of any in-line table code, for example;
<%
Dim item, items
'Build the array from the Views comma separated string
Views = Split(Views, ",")
'Always include Table One
Call ShowTable("one")
'Check we have an Array built from the Split().
If IsArray(Views) Then
'How many views have we requested?
items = UBound(Views)
For item = 0 To items
'What view are we current looking at in the loop?
Call ShowTable(views(item))
Next
End If
%>
Your output will then look something like this (if you pass "Two, Three") for example;
<table>
<tr>
<td>Table For View One</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Two</td>
</tr>
</table>
<table>
<tr>
<td>Table For View Three</td>
</tr>
</table>
Update based on OP feedback
If you don't want multiple tables (which is not clear from your question) then just remove the <table> and </table> in-line definitions (in the ShowTable() procedure), this will create the "guts" of your table (a series of table rows).
Then in the example code above just add <table> at the start and after the code </table>, which will encapsulate your dynamically generated table rows into one table.
<table>
<%
Dim item, items
'Build the array from the Views comma separated string
Views = Split(Views, ",")
'Always include Table One
Call ShowTable("one")
'Check we have an Array built from the Split().
If IsArray(Views) Then
'How many views have we requested?
items = UBound(Views)
For item = 0 To items
'What view are we current looking at in the loop?
Call ShowTable(views(item))
Next
End If
%>
</table>
Your output will then look something like this (if you pass "Two, Three") for example;
<table>
<tr>
<td>Table For View One</td>
</tr>
<tr>
<td>Table For View Two</td>
</tr>
<tr>
<td>Table For View Three</td>
</tr>
</table>