Graph and save serial data into processing - arduino

Question

Just wanted to say I've been using the forums to learn a lot so thank you to all contributors and supporters of stack overflow.
I'm a student new to processing/arduino and I'm trying to make a processing sketch that takes serial data and graphs multiple sensor values on different graphs, while having the ability for the user to record all data into a CSV. Also I was wondering how to make a simple text box that updated and printed one of the sensor values.
A very basic snippet of my arduino serial printout code includes:
Serial.print(sensor1);
Serial.print(",");
Serial.print(sensor2);
Serial.print(",");
Serial.print(sensor3);
Serial.println(",");
//Sensor1 and 2, would be on separate graphs, and 3 would be a single printed value updated frequently.
For processing I've seen very basic examples and was wondering if what would be easier/better: to do a direct graph using the map function or to setup a cgraph and cdata arrays (saw in another example). Lastly while using a create writer or filewriter for saving data, is there a way to have new files being created rather than overwriting or appending data? Could I use an if statement to get user input text to type in the filename to avoid an overwrite?
I would be greatful for any hints or help.

Answer 1

You should probably send a new line character at the end:
Serial.print(sensor1);
Serial.print(",");
Serial.print(sensor2);
Serial.print(",");
Serial.print(sensor3);
Serial.println();
Once that's done you can use Serial's bufferUntil() to keep track of each line for you. Then in serialEvent() you can simply readString()
In terms of saving to a CSV file, you can append each line to an ArrayList.
(Alternatively you can used a typical String[] but you have to manually manage the line index and expand() the array when new lines come in. ArrayList may be simpler). Whenever you want to save the CSV file, you can easily convert the ArrayList to a String[] which is what saveStrings() expects. In terms of saving new files, you can simply create a timestamp string:
import processing.serial.*;
//serial port
Serial arduino;
//timestamp used for CSV filename
String timestamp;
//current CSV line received from Arduino
String currentLine = "";
//all lines received from Arduino
ArrayList<String> csvData = new ArrayList<String>();
void setup(){
try{
//be sure use the correct port/baud rate
arduino = new Serial(this,"/SERIAL_PORT_HERE",115200);
arduino.bufferUntil('\n');
}catch(Exception e){
System.err.println("Error initializing serial port!\nPlease check the PORT NAME, BAUD RATE and USB connections\nAlso close Serial Monitor or other serial port connections (if any)");
e.printStackTrace();
}
}
void draw(){
background(0);
text(currentLine,10,15);
}
void serialEvent(Serial s){
//read data from serial port
currentLine = s.readString();
//append data to be later saved as a CSV file
csvData.add(currentLine);
//process current values - update plot, not fully implemented
processCurrentLine();
}
void processCurrentLine(){
//parse and update plot here
try{
String[] values = currentLine.split(",");
printArray(values);
}catch(Exception e){
e.printStackTrace();
}
}
void saveCSV(){
//create a timestamp to be used for the CSV filename (avoiding the file being overwritten
timestamp = day()+"-"+month()+"-"+year()+" "+hour()+":"+minute()+":"+second();
println("saving CSV file");
saveStrings(timestamp+".csv",csvData.toArray(new String[csvData.size()]));
}
//save on 's' key
void keyReleased(){
if(key == 's') saveCSV();
}
//save on exit
void exit(){
saveCSV();
super.exit();
}
If you're on Windows, you might want to checkout SerialChart.
It's a nice simple Qt based UI for rendering graphcs based on CSV formatted Serial data. It should also allow you to save the data and it provides a few configuration settings too.
Update
I have recently noticed Arduino 1.6.6 (or newer) has a built in Serial Plotter