NEO4J CYPHER Query to Group By a Sorted Query - collections

Question

I am having a hard time coming up with the right CYPHER query for a use case:
I have USER and HOBBY as nodes. Comment is relationship on User's Hobbies. User can have many Hobbies and other Users can COMMENT on Hobbies of User.
Problem: Show the HOBBIES and COMMENTS with latest Comments for a User sorted by the most recent ones.
The query I am trying to perform is:
MATCH (u:user)-[r:comment]->(n:Hobby)
WHERE has(r.`comment`) and u.id = 'Test'
RETURN
DISTINCT n.id,n.name, n.description, COLLECT(r.id) as `comment`
ORDER BY
r.creationdate DESC
Apparently, r.creationdate can't be used to sort within a grouped result. Is there an alternative?

Answer 1

Try imposing order before aggregation. How about
MATCH (u:user {id:'test'})-[r:comment]->(n:Hobby)
WHERE has(r.comment)
WITH n, r
ORDER BY r.creationdate
RETURN n.id, n.name, n.description, COLLECT(r.id) as comment
(Sidenote: I'd recommend 'idiomatic' or at least consistent style for your queries, i.e. type labels like you would your name ((:User)) and relationship types as if you were shouting on the internet ([:COMMENT]). This makes no difference for validity or performance, but it's just nice and it helps avoid silly mistakes to follow even arbitrary conventions.)

Answer 2

you don't need distinct in your case, aggregation already makes distinct
r doesn't exist anymore at the point where you want to sort it.
Either you don't collect, then you can sort by it,
or you sort it upfront with WITH.
or you sort by min(r.creationdate) or max(r.creationdate)
for number 2:
MATCH (u:user)-[r:comment]->(n:Hobby)
WHERE has(r.`comment`) and u.id = 'Test'
WITH
n, r.id as rid
ORDER BY
r.creationdate DESC
RETURN n.id,n.name, n.description, collect(rid) as comment
for number 3:
MATCH (u:user)-[r:comment]->(n:Hobby)
WHERE has(r.`comment`) and u.id = 'Test'
RETURN
DISTINCT n.id,n.name, n.description, COLLECT(r.id) as `comment`, max(r.creationdate)
ORDER BY
max(r.creationdate) DESC