Tooltips in .swf loaded with SWFLoader cause error #1009 - apache-flex

Question

I am working on a flex web project where a lot of the functionality is modular and the SWFs are loaded with SWFLoader. I've recently created a module which has tooltips on some elements and I was getting a runtime error #1009 when hovering over these elements to see the tooltip. If, instead of loading the SWF with SWFLoader at runtime, I instantiate it in the application directly, the tooltips work fine. Does anyone know why this is?
I'm using Flex SDK 4.5.1 because one of the libs I have to use doesn't work with later versions.
I've isolated the issue into a small example. Here's the code:
main mxml:
<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600"
backgroundColor="#000000"
creationComplete="onComplete(event);">
<fx:Script>
<![CDATA[
import mx.controls.SWFLoader;
import mx.events.FlexEvent;
private function onComplete(event:FlexEvent):void {
// Comment this block out to try without loading external swf
var swfLoader:SWFLoader = new SWFLoader();
swfLoader.addEventListener(Event.COMPLETE, swfLoadComplete);
swfLoader.load("ExternalSWF.swf");
// Uncomment this block to try without loading external swf ... Notice the tooltips suddenly work..
/*var externalSwf:ExternalSWF = new ExternalSWF();
this.addElement(externalSwf);*/
}
private function swfLoadComplete(event:Event):void {
var externalSwf:ExternalSWF = (event.target as SWFLoader).content as ExternalSWF;
this.addElement(externalSwf);
}
]]>
</fx:Script>
<fx:Declarations>
<!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
</s:Application>
ExternalSWF class (in flash builder 4.7, this is set to compile as a module):
package
{
import spark.components.Button;
import spark.components.VGroup;
[Frame(factoryClass="ExternalSWF")]
public class ExternalSWF extends VGroup
{
public function ExternalSWF()
{
super();
var btn:Button = new Button();
btn.label = "mouse over this";
btn.toolTip = "moused over";
this.addElement(btn);
}
}
}

Answer 1

Thanks, Zeus. That set me on the correct path and I was able to solve my problem.
Here's one solution:
main mxml AS code:
private var _info:IModuleInfo;
private function onComplete(event:FlexEvent):void {
_info = ModuleManager.getModule("ExternalSWF.swf");
_info.addEventListener(ModuleEvent.READY, modEventHandler);
_info.load(null, null, null, moduleFactory);
}
private function modEventHandler(event:ModuleEvent):void {
var externalSwf:ExternalSWF = _info.factory.create() as ExternalSWF;
this.addElement(externalSwf);
}
ExternalSWF
package
{
import mx.controls.Button;
import spark.modules.Module;
public class ExternalSWF extends Module
{
public function ExternalSWF()
{
super();
var btn:Button = new Button();
btn.label = "mouse over this";
btn.toolTip = "moused over";
this.addElement(btn);
}
}
}