implementing a state machine for servo motors - arduino

Question

I have created a FSM for my servo. It has two states. I am using a switch/case structure but the motor is getting 'stuck' in the first case and Im not sure why.
This is my code:
#include <Servo.h>
#define one 1
#define two 2
Servo myservo1; //projector platform servo
unsigned long Timer1; //define timer variable for state 1 if statement
void setup()
{
myservo1.attach(9);
}
void loop(){
static int state = one; // initial state is one.
switch(state)
{
case one:
myservo1.writeMicroseconds(1374); // servo is moving cw
delay(5000);
myservo1.writeMicroseconds(1474); // servo is stationary
Timer1 = millis();
if (millis() - Timer1 > 5000)
{
state = two;
}
break;
case two:
for(int speedv1 = 0; speedv1 <= 100; speedv1 += 2) // loop to ramp up speed of servos
{
myservo1.writeMicroseconds(1474 + speedv1); // speed increase by 2 each iteration (servo 1) until servo reaches fullspeed (ACW)
delay(40); // delay between loop iterations
}
delay(5000);
for(int speedv2 = 0; speedv2 <= 100; speedv2 += 2) // loop to ramp down servo speed
{
myservo1.writeMicroseconds(1574 - speedv2); // speed decrease by 2 each iteration (servo 1) until servo stops
delay(40); //delay between loop iterations
}
delay(2000);
state = one;
break;
}
}
The motor seems to get stuck at
myservo1.writeMicroseconds(1374);
on the first line of case 1.
By stuck I mean the motor just continues to rotate in a clockwise fashion and does not progress to the next writeMicroseconds() statement after the delay. Appreciate the help.

Answer 1

With this piece of code in state one:
Timer1 = millis();
if (millis() - Timer1 > 5000)
{
state = two;
}
it's incredibly unlikely that the timer will have advance five seconds between the first and second line. Hence because you change Timer1 everyone time you run that bit of code, it will alway stay in state one.
Though it's unclear what exactly you're trying to achieve (I'm uncertain as to what the writeMicroSeconds() calls do, nor your need for the explicit delays within the states themselves), let's assume for now that you want to stay in state one for five seconds but do something else during that time. That means you need to initialise the start time as part of moving to state one, not within the state one code itself.
For example, the following code shows one way to do this, continuously running the servo clockwise for five seconds then anti-clockwise for four (with some mythical calls to start the servo running):
void loop() {
static int state = zero;
static unsigned long timer1;
switch (state) {
case zero: {
timer1 = millis();
state = one;
servo.startClockwise();
break;
}
case one: {
if (millis() - timer1 >= 5000) {
servo.stop();
servo.startAntiClockwise();
timer1 = millis();
state = two;
} else {
doSomethingElse();
}
break;
}
case two: {
if (millis() - timer1 >= 4000) {
servo.stop();
servo.startClockwise();
timer1 = millis();
state = one;
} else {
doSomethingElse();
}
break;
}
}
}