Most efficient way to validate multiple textboxes against a tolerance value - asp.net

Question

I have a series of text boxes in a table to gather input as below:
The user will input a target and actual value for each measurement point they require. I would then like to validate the actual values against the target values based upon the tolerance inputted in the tolerance textbox. The tolerance will be the same for all measurement points inputted, however the user will not always input all 10 measurement points.
I have also created a very basic class containing a function that accepts the target, actual and tolerance values then returns a Boolean depending on whether the actual value is within tolerance. I realise I could use this with a ruck load of if statements to check each textbox for input then use the class to perform the validation, however this seems like a lot of code repetition and a bit crude. My question being is there a better way I can perform this validation?
EDIT Class content
Public Class TolerenceHelper
Public Function IsInTolerence(ByVal target As Integer, ByVal actual As Integer, ByVal tolerence As Integer) As Boolean
Dim upper As Integer = target + tolerence
Dim lower As Integer = target - tolerence
If actual < lower OrElse actual > upper Then
Return False
Else
Return True
End If
End Function
Calling the function as below:
Dim m1 As TolerenceHelper
Dim flag As Boolean = True
m1 = New TolerenceHelper
If m1.IsInTolerence(Integer.Parse(txtT1.Text), Integer.Parse(txtA1.Text), Integer.Parse(txtTolerance.Text)) = False Then
flag = False
End If
If flag = False Then
lblTest.Text = "Out of tolerance"
Else
lblTest.Text = "In tolerance"
End If

Answer 1

Your helper method seems to be ok, but you haven't shown the important part that you want to improve. The part where you load all textboxes and check whether they are valid or not.
Here is an approach that uses a custom class Measurement. You can use
Math.Abs(target.Value - actual.Value) <= tolerance
to determine if the value is valid according to the target and the tolerance.
Public Class Measurement
Public Property Tolerance As Int32
Public Property Target As Int32
Public Property Value As Int32
Public ReadOnly Property IsValid As Boolean
Get
Return Math.Abs(Target - Value) <= Tolerance
End Get
End Property
End Class
I would add all textboxes into the same container control like a Panel. Then you could use Enumerable.OfType to find the relevant textboxes. I use Enumerable.Zip to bring the values and the targets together. Use Int32.TryParse to validate the text.
Dim tolerance As Int32
If Not Int32.TryParse(txtTolerance.Text, tolerance) Then
lblTest.Text = "Enter a valid tolerance! Tolerance must be a positive integer(incl. zero)."
Return
End If
Dim value As Int32
Dim allTxtTarget = From txt In Me.PnlMeasurement.Controls.OfType(Of TextBox)()
Where txt.ID Like "txtT#*" AndAlso Int32.TryParse(txt.Text, value)
Let x = New With {.TextBox = txt, .Value = value, .Type = "Target", .Number = txt.ID.Substring(4)}
Order By x.Number
Select x
Dim allTxtActual = From txt In Me.PnlMeasurement.Controls.OfType(Of TextBox)()
Where txt.ID Like "txtA#*" AndAlso Int32.TryParse(txt.Text, value)
Let x = New With {.TextBox = txt, .Value = value, .Type = "Value", .Number = txt.ID.Substring(4)}
Order By x.Number
Select x
Dim allMeasurements = allTxtTarget.Zip(allTxtActual,
Function(target, actual) New Measurement With {
.Tolerance = tolerance,
.Target = target.Value,
.Value = actual.Value
}).ToList()
Output the results:
For i As Int32 = 0 To allMeasurements.Count - 1
Dim m = allMeasurements(i)
Console.WriteLine("Measurement {0}: Tolerance:{1} Target:{2} Value:{3} Valid:{4}",
i+1, tolerance, m.Target, m.Value, m.IsValid)
Next
If you actually need to check if all or at least one measurement is valid you can use:
Dim allValid = allMeasurements.All(Function(m) m.IsValid)
Dim anyValid = allMeasurements.Any(Function(m) m.IsValid)
or to find the highest valid measurement:
Dim validMeasurements = From m In allMeasurements
Where m.IsValid
Order By m.Value Descending
Dim highestMeasurement = validMeasurements.FirstOrDefault()