Get a Number from String with no default decimal separator - apache-flex

Question

I have a TextInput where a need to return a Number.
My problem is that entered value is localized to a logged in user and that effects the decimal separator.
I seem to always get a NaN when i try to get a Number from a Polish user but it works great for English users:
Input example:
English: 23.5
Polish: 23,5
Is there a workaround for this? I have the following that doesn't work:
public function get myValue():Number {
var value:Number = new Number(StringUtil.trim(text)); //NaN with Polish
return value;
}
I have also tried the following but it also gives a NaN:
private function myValue(number:Number, precision:Number=2):Number{
var numberFormatter:NumberFormatter = getNumberFormatter(precision);
return new Number(numberFormatter.formatNumber(number));
}
private function getNumberFormatter(precision:Number=2):NumberFormatter{
var iso:String = ClientInfo.instance.language.ISOCode;
var formattedIso:String = iso.substr(0, 2)+'_'+iso.substr(2,2);
var numberFormatter:NumberFormatter = new NumberFormatter(formattedIso);
numberFormatter.fractionalDigits = precision;
numberFormatter.trailingZeros = true;
return numberFormatter;
}
When I debug the code I can see that the NumberFormatter works correctly but its always the call to new Number("23,5") that gives a NaN.

Answer 1

Can't test it now, but I guess it should work:
public function get myValue():Number
{
var value:Number = getNumberFormatter.parseNumber(StringUtil.trim(text));
return value;
}
I think the key is, that you should use parseNumber()!
[Update]
Here is a FlexUnit test for better understanding:
[Test]
public function test(): void
{
var number: Number = new NumberFormatter("de-DE").parseNumber("23,5");
assertEquals(23.5, number);
number = new NumberFormatter("en-US").parseNumber("23.5");
assertEquals(23.5, number);
number = new NumberFormatter("de-DE").parseNumber("1.023,456");
assertEquals(1023.456, number);
number = new NumberFormatter("pl-PL").parseNumber("1023,45");
assertEquals(1023.45, number);
number = new NumberFormatter("pl-PL").parseNumber("1.023,45");
assertTrue(isNaN(number));
number = new NumberFormatter("pl-PL").parseNumber("1 023,45");
assertEquals(1023.45, number);
number = new NumberFormatter("pl-PL").parseNumber(" 10 531 023,45 ");
assertEquals(10531023.45, number);
}
As you can see NumberFormatter handles decimal and thousands separator correctly.
If you want to format it back, then you could use it like this:
var numFmt: NumberFormatter = new NumberFormatter("pl-PL");
assertEquals("23,50", numFmt.formatNumber(numFmt.parseNumber(" 23,5 ")));
numFmt.fractionalDigits = 1;
assertEquals("23,6", numFmt.formatNumber(numFmt.parseNumber(" 23,57 ")));

Answer 2

Assuming your numbers are not being returned with commas between each 10^3 number group (i.e. 1,000,000 for 1 million), you could just use a replace on the commas.
Number("23,5".replace(",","."); // output Number( "23.5" ) = 23.5
That will replace all commas in the number with a period and should be read as a normal number by the system.