How do i handle Remote Method calls via AsyncToken? - apache-flex

Question

So here is the mxml i would like to get working:
<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600">
<fx:Script>
<![CDATA[
import argoseye.main.Golem;
import mx.collections.ArrayCollection;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.Responder;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.InvokeEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.remoting.RemoteObject;
protected function button1_clickHandler(event:MouseEvent):void
{
var ro:RemoteObject = new RemoteObject("destination");
ro.endpoint = "http://Jesus/blazeds/messagebroker/amf";
ro.addEventListener(InvokeEvent.INVOKE,onInvoke);
var token:AsyncToken = new AsyncToken();
token.addResponder(new AsyncResponder(onResult,onFault));
token = ro.getCells();
textfeld.text = textfeld.text + "Clickhandler called .... \n";
}
public function onResult(event:ResultEvent,token:Object):void {
textfeld.text = textfeld.text + "Resulthandler called .... \n";
var cellList:ArrayCollection = event.result as ArrayCollection;
}
public function onFault(event:FaultEvent,token:Object):void
{
textfeld.text = textfeld.text + "Faulthandler called .... \n";
}
public function onInvoke(event:InvokeEvent):void {
textfeld.text = textfeld.text + "Invokehandler called .... \n";
}
]]>
</fx:Script>
<fx:Declarations>
<!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<s:Button x="1093" y="575" label="Button" click="button1_clickHandler(event)"/>
<s:TextArea x="1022" y="183" id="textfeld"/>
</s:Application>
The output is
Invokehandler called ....
Clickhandler called ....
The Resulthandler doesnt get called, allthough the BlazeDS Console registers an successfull Resultevent. What do I do wrong?
Edit: I tried exporting the procedure into a class, which is supposed to manage these things.
package argoseye.main
{
import flash.events.Event;
import mx.collections.ArrayCollection;
import mx.messaging.ChannelSet;
import mx.messaging.channels.AMFChannel;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.remoting.RemoteObject;
public class Schem
{
public var info:String="";
public function Schem()
{
}
public function loadCurrentSchem():void
{
var ro:RemoteObject = new RemoteObject("Hibernatetest");
ro.endpoint = "http://jesus/blazeds/messagebroker/amf";
var token:AsyncToken = ro.getCells();
token.addResponder(new AsyncResponder(onResult,onFault));
info = info + "Loader Called ...";
}
public function onResult(event:ResultEvent,token:Object):void {
var cellList:ArrayCollection = event.result as ArrayCollection;
info = info + "Resulthandler Called";
}
public function onFault(event:FaultEvent,token:Object):void
{
}
//Eventhandlers
//Getters, Setters
}
}
If i call it, it doesnt reach the eventhandler. Where is my mistake?

Answer 1

Your error lies in these lines:
var token:AsyncToken = new AsyncToken();
token.addResponder(new AsyncResponder(onResult,onFault));
token = ro.getCells();
You're creating a new token on line 1.
You assign a responder on line 2.
And then you reassign the token on line 3.
What you do on line 3 is effectively creating a new token, thus it doesn't have the responder attached to it, because it's a new instance.
So it should be:
var token:AsyncToken = ro.getCells();
//ro.getCells() will return a new instance of AsyncToken
token.addResponder(new AsyncResponder(onResult,onFault));

Answer 2

Use the following code:
<fx:Script>
<![CDATA[
import argoseye.main.Golem;
import mx.collections.ArrayCollection;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.Responder;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.InvokeEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.remoting.RemoteObject;
protected function button1_clickHandler(event:MouseEvent):void
{
var ro:RemoteObject = new RemoteObject("destination");
ro.endpoint = "http://Jesus/blazeds/messagebroker/amf";
ro.addEventListener(InvokeEvent.INVOKE,onInvoke);
var token:AsyncToken = ro.getCells();
token.addResponder(new AsyncResponder(onResult,onFault));
textfeld.text = textfeld.text + "Clickhandler called .... \n";
}
public function onResult(event:ResultEvent,token:Object):void {
textfeld.text = textfeld.text + "Resulthandler called .... \n";
var cellList:ArrayCollection = event.result as ArrayCollection;
}
public function onFault(event:FaultEvent,token:Object):void
{
textfeld.text = textfeld.text + "Faulthandler called .... \n";
}
public function onInvoke(event:InvokeEvent):void {
textfeld.text = textfeld.text + "Invokehandler called .... \n";
}
]]>
</fx:Script>
<fx:Declarations>
<!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<s:Button x="1093" y="575" label="Button" click="button1_clickHandler(event)"/>
<s:TextArea x="1022" y="183" id="textfeld"/>