How to perform feature Normalize in Julia? - julia

Question

I have written a "featureNormalize" function for Andrew Ng's machine learning course in Julia.
It works for input feature but for predicting the output values if I input as
predict = featureNormalize([1650 3])
The output is
1×2 Matrix{Float64}:
NaN NaN
function featureNormalize(X)
mu = mean(X,dims=1)
sigma = std(X,dims=1)
X_norm = (X .- mu) ./ sigma
return X_norm
end

Answer 1

You need a data set with at least two examples in order to compute std, otherwise it will return NaN. If you really need to consider this corner case, you can introduce an if-else branch in the function body.

Answer 2

You may want to consider that sometimes you need to skip some features from the normalisation or that you may need to revert the normalisation (when you normalise y).
Here is an example that accounts for these two cases (from BetaML.jl):
"""julia
getScaleFactors(x;skip)
Return the scale factors (for each dimensions) in order to scale a matrix X (n,d)
such that each dimension has mean 0 and variance 1.
# Parameters
- `x`: the (n × d) dimension matrix to scale on each dimension d
- `skip`: an array of dimension index to skip the scaling [def: `[]`]
# Return
- A touple whose first elmement is the shift and the second the multiplicative
term to make the scale.
"""
function getScaleFactors(x;skip=[])
μ = mean(x,dims=1)
σ² = var(x,corrected=false,dims=1)
sfμ = - μ
sfσ² = 1 ./ sqrt.(σ²)
for i in skip
sfμ[i] = 0
sfσ²[i] = 1
end
return (sfμ,sfσ²)
end
"""
scale(x,scaleFactors;rev)
Perform a linear scaling of x using scaling factors `scaleFactors`.
# Parameters
- `x`: The (n × d) dimension matrix to scale on each dimension d
- `scalingFactors`: A tuple of the constant and multiplicative scaling factor
respectively [def: the scaling factors needed to scale x to mean 0 and variance 1]
- `rev`: Whether to invert the scaling [def: `false`]
# Return
- The scaled matrix
# Notes:
- Also available `scale!(x,scaleFactors)` for in-place scaling.
- Retrieve the scale factors with the `getScaleFactors()` function
"""
function scale(x,scaleFactors=(-mean(x,dims=1),1 ./ sqrt.(var(x,corrected=false,dims=1))); rev=false )
if (!rev)
y = (x .+ scaleFactors[1]) .* scaleFactors[2]
else
y = (x ./ scaleFactors[2]) .- scaleFactors[1]
end
return y
end
function scale!(x,scaleFactors=(-mean(x,dims=1),1 ./ sqrt.(var(x,corrected=false,dims=1))); rev=false)
if (!rev)
x .= (x .+ scaleFactors[1]) .* scaleFactors[2]
else
x .= (x ./ scaleFactors[2]) .- scaleFactors[1]
end
return nothing
end