Oracle PL/SQL Script vs SQL in SQL Developer ( Invalid Alter Option) - plsql

Question

I am in the process of trying to create multiple PL/SQL Scripts to help maintain our existing databases and allow us to make modifications to them. The first one I'm working on is shown below:
BEGIN
-- add the field to the table that will be used to check against when
-- looking for records that need to be processed.
EXECUTE IMMEDIATE('
ALTER TABLE TBL_SAP_VENDORS_COPY
ADD UPT_TS TIMESTAMP ;
');
-- The automatic update of fields has to be performed using a trigger
-- First we drop the trigger incase it already exists
Execute Immediate ('
drop trigger vendors_updt_mark;
');
EXECUTE IMMEDIATE ('
-- Then add the trigger deffinition
CREATE TRIGGER vendors_updt_mark
before insert or update
on TBL_SAP_VENDORS_COPY
FOR EACH ROW
BEGIN
:new.UPT_TS := SYSTIMESTAMP;
END;
');
END;
I'm having problems with the very 1st statement which is the alter statement:
ALTER TABLE TBL_SAP_VENDORS_COPY
ADD UPT_TS TIMESTAMP ;
When I execute it using the 'Run Script' option in Oracle SQL Developer I get the following error:
Error starting at line : 1 in command -
BEGIN
-- add the field to the table that will be used to check against when
-- looking for records that need to be processed.
EXECUTE ('
ALTER TABLE TBL_SAP_VENDORS_COPY
ADD UPT_TS TIMESTAMP ;
');
-- The automatic update of fields has to be performed using a trigger
-- First we drop the trigger incase it already exists
Execute Immediate ('
drop trigger vendors_updt_mark;
');
EXECUTE IMMEDIATE ('
-- Then add the trigger deffinition
CREATE TRIGGER vendors_updt_mark
before insert or update
on TBL_SAP_VENDORS_COPY
FOR EACH ROW
BEGIN
:new.UPT_TS := SYSTIMESTAMP;
END;
');
END;
Error report -
ORA-06550: line 4, column 5:
PLS-00201: identifier 'EXECUTE' must be declared
ORA-06550: line 4, column 5:
PL/SQL: Statement ignored
06550. 00000 - "line %s, column %s:\n%s"
*Cause: Usually a PL/SQL compilation error.
*Action:
Error starting at line : 1 in command -
BEGIN
-- add the field to the table that will be used to check against when
-- looking for records that need to be processed.
EXECUTE IMMEDIATE('
ALTER TABLE TBL_SAP_VENDORS_COPY
ADD UPT_TS TIMESTAMP ;
');
-- The automatic update of fields has to be performed using a trigger
-- First we drop the trigger incase it already exists
Execute Immediate ('
drop trigger vendors_updt_mark;
');
EXECUTE IMMEDIATE ('
-- Then add the trigger deffinition
CREATE TRIGGER vendors_updt_mark
before insert or update
on TBL_SAP_VENDORS_COPY
FOR EACH ROW
BEGIN
:new.UPT_TS := SYSTIMESTAMP;
END;
');
END;
Error report -
ORA-01735: invalid ALTER TABLE option
ORA-06512: at line 4
01735. 00000 - "invalid ALTER TABLE option"
*Cause:
*Action:
When is execute the same statement by itself in SQL Developer is executes with not problem.'

Answer 1

You want:
brackets around the column definition;
to remove the trailing semi-colon in the EXECUTE IMMEDIATE strings when you are executing an SQL command (however, it is required for PL/SQL blocks); and
to catch the exception if the trigger does not exist when you try to drop it.
Like this:
BEGIN
-- add the field to the table that will be used to check against when
-- looking for records that need to be processed.
EXECUTE IMMEDIATE('ALTER TABLE TBL_SAP_VENDORS_COPY ADD ( UPT_TS TIMESTAMP )');
-- The automatic update of fields has to be performed using a trigger
-- First we drop the trigger incase it already exists
DECLARE
trigger_not_found EXCEPTION;
PRAGMA EXCEPTION_INIT( trigger_not_found, -4080 );
BEGIN
Execute Immediate ('drop trigger vendors_updt_mark');
EXCEPTION
WHEN trigger_not_found THEN
NULL;
END;
-- Then add the trigger deffinition
EXECUTE IMMEDIATE ('
CREATE TRIGGER vendors_updt_mark
before insert or update
on TBL_SAP_VENDORS_COPY
FOR EACH ROW
BEGIN
:new.UPT_TS := SYSTIMESTAMP;
END;
');
END;
/
db<>fiddle here