Turn off analog pins if no serial data for x seconds - arduino

Question

I have a program on my computer that sends serial data to my Arduino that dictates the analog write on the Arduino. How can I check if no new serial data has been sent for x seconds and if there isn't do something. E.G:
if (newDataInLastSeconds(10) {
// Do Something...
}```

Answer 1

For this problem you can use a state machine that tracks the state of the serial link, and setup actions that trigger on state transitions. If you also want to setup actions that happen every loop() depending on the state of the link, that's even easier to set up (not shown).
You're likely already checking Serial.available() to see if there are any bytes received on the serial line, correct? All you need to do is create a very simple two-state state machine:
Determine the timeout you want
Keep track of what state the data timeout is in (bool serial_fresh -- you've either received data recently or not)
Keep a record of the last time you received any data
If the serial line is fresh, compare the current time to the previous time. If greater than your timeout, then set fresh to false (this is a state transition) and do the action you want to do
If the serial line is not fresh, and you just received data, then set fresh to true (another state transition) and do the action you want to do on that transition
// start in the unfresh state, we won't transition to fresh until
// we receive the first byte - if this doesn't match what you want change to fit
bool g_serial_fresh = false;
const unsigned long SERIAL_TIMEOUT_MS = 5000; // or however many milliseconds
unsigned long g_last_serial_rx_ms = 0;
void transitionToFresh() {
g_serial_fresh = true;
/* do what you want to do when the link comes back up - turn on ADC */
}
void transitionToStale() {
g_serial_fresh = false;
/* do what you want to do when the link times out - shutdown ADC */
}
bool serialTimedOut() {
return (millis() - g_last_serial_rx_ms) > SERIAL_TIMEOUT_MS;
}
void doStateMachine() {
bool received_data_this_loop = false;
if (Serial.available() > 0) { // assumes you read all available bytes later
g_last_serial_rx_ms = millis();
received_data_this_loop = true;
}
if (!g_serial_fresh && received_data_this_loop) {
transitionToFresh();
}
else if (g_serial_fresh && serialTimedOut()) {
transitionToStale();
}
}
void loop() {
doStateMachine();
/* do regular programmy things here */
}

Answer 2

You can make a function with a while loop that checks for new data during a specific amount of time by using the Serial.available function:
boolean newDataInInterval(long waitInterval){
long startTime = millis();
while (millis() <= (startTime+waitInterval)) {
if (Serial.available() > 0) {
return true;
}
}
return false;
}
Note that waitInterval should be given in milliseconds.