Existance proofs with polymorphic types - isabelle

Question

I am trying to formalize the proof that DFA are closed under union, and I have got so far as proving "∀ 𝒜 ℬ. language 𝒜 ∪ language ℬ = language (DFA_union 𝒜 ℬ)", but what I would actually like to prove is ∀ 𝒜 ℬ. ∃ 𝒞. language 𝒜 ∪ language ℬ = language 𝒞. I belive the issue has something to do with polymorphic types, but I am not sure.
Here is what I have:
declare [[show_types]]
declare [[show_sorts]]
declare [[show_consts]]
record ('q, 'a)DFA =
Q0 :: 'q
F :: "'q set"
δ :: "'q ⇒ 'a ⇒ 'q"
primrec δ_iter :: "('q, 'a)DFA ⇒ 'a list ⇒ 'q ⇒ 'q" where
"δ_iter 𝒜 [] q = q" |
"δ_iter 𝒜 (a # as) q = δ_iter 𝒜 as (δ 𝒜 q a)"
definition δ0_iter :: "('q, 'a)DFA ⇒ 'a list ⇒ 'q" where
"δ0_iter 𝒜 as = δ_iter 𝒜 as (Q0 𝒜)"
definition language :: "('q, 'a)DFA ⇒ ('a list) set" where
"language 𝒜 = {w . δ0_iter 𝒜 w ∈ (F 𝒜)}"
fun DFA_union :: "('p, 'a)DFA ⇒ ('q, 'a)DFA ⇒ ('p × 'q, 'a)DFA" where
"DFA_union 𝒜 ℬ =
⦇ Q0 = (Q0 𝒜, Q0 ℬ)
, F = {(q, r) . q ∈ F 𝒜 ∨ r ∈ F ℬ}
, δ = λ (q, r). λ a. (δ 𝒜 q a, δ ℬ r a)
⦈"
lemma extract_fst: "∀ 𝒜 ℬ p q. fst (δ_iter (DFA_union 𝒜 ℬ) ws (p, q)) = δ_iter 𝒜 ws p"
by (induct ws; simp)
lemma extract_snd: "∀ 𝒜 ℬ p q. snd (δ_iter (DFA_union 𝒜 ℬ) ws (p, q)) = δ_iter ℬ ws q"
by (induct ws; simp)
lemma "∀ 𝒜 ℬ. language 𝒜 ∪ language ℬ = language (DFA_union 𝒜 ℬ)"
proof((rule allI)+)
fix 𝒜 ℬ
let ?𝒞 = "DFA_union 𝒜 ℬ"
have "language ?𝒞 = {w . δ0_iter ?𝒞 w ∈ F ?𝒞}"
by (simp add: language_def)
also have "... = {w . fst (δ0_iter ?𝒞 w) ∈ (F 𝒜) ∨ snd (δ0_iter ?𝒞 w) ∈ (F ℬ)}"
by auto
also have "... = {w . δ0_iter 𝒜 w ∈ F 𝒜 ∨ δ0_iter ℬ w ∈ F ℬ}"
using DFA.select_convs(1) DFA_union.simps δ0_iter_def extract_fst extract_snd
by (metis (no_types, lifting))
also have "... = {w . δ0_iter 𝒜 w ∈ F 𝒜} ∪ {w. δ0_iter ℬ w ∈ F ℬ}"
by blast
also have "... = language 𝒜 ∪ language ℬ"
by (simp add: language_def)
finally show "language 𝒜 ∪ language ℬ = language ?𝒞"
by simp
qed
lemma DFA_union_closed: "∀ 𝒜 ℬ. ∃ 𝒞. language 𝒜 ∪ language ℬ = language 𝒞"
sorry
If I add types to 𝒜 or ℬ in the main lemma I get "Failed to refine any pending goal".

Answer 1

the problem is indeed because of implicit types. In your last statement Isabelle implicitly infers state-types 'p, 'q, 'r for the three automata A, B, C,
whereas your DFA_union lemma fixes the state type of C to 'p * 'q. Therefore, if you have to explicitly provide type-annotations. Moreover, it is usually not required to state your lemmas with explicit ∀-quantifiers.
So, you can continue like this:
lemma DFA_union: "language 𝒜 ∪ language ℬ = language (DFA_union 𝒜 ℬ)"
(is "_ = language ?𝒞")
proof -
have "language ?𝒞 = {w . δ0_iter ?𝒞 w ∈ F ?𝒞}"
...
qed
lemma DFA_union_closed: fixes 𝒜 :: "('q,'a)DFA" and ℬ :: "('p,'a)DFA"
shows "∃ 𝒞 :: ('q × 'p, 'a)DFA. language 𝒜 ∪ language ℬ = language 𝒞"
by (intro exI, rule DFA_union)
Note that these type-annotations are also essential in the following sense.
A lemma like the following (where all state-types are the same) is just not true.
lemma fixes 𝒜 :: "('q,'a)DFA" and ℬ :: "('q,'a)DFA"
shows "∃ 𝒞 :: ('q, 'a)DFA. language 𝒜 ∪ language ℬ = language 𝒞"
The problem is, plug in the bool-type for 'q, then you have automata which
have at most two states. And then you cannot always find an automaton for the union that also has at most two states.