Age gate during install when using an NSIS package - datetime

Question

I have no idea if anyone has attempted this before (and especially considering the standards for this) but has anyone ever programmed an age gate into an NSIS installer for apps that revolve around restricted themes, content or entertainment? I ask this for the most obvious of common reasons by which a reputable marketplace would otherwise reject your submission:
The presence of sexual themes (as in "fifty shades" if you want to be extra specific)
Apps referencing the use or depiction of regulated products (beer, cannabis, vaping)
Games with extreme language or suggestive themes (ESRB Class M or equivalent)
Any ideas?

Answer 1

For actual games, you can register them with Windows Games Explorer. IGameExplorer::VerifyAccess can tell you if the game is blocked by parental controls. While you technically can call this method in the installer, it might give the wrong results if your installer requests UAC elevation because the installer might run under the parents account, not the child's account. The game should call it every time it is started. The Game Explorer API seems to be crippled in newer versions of Windows 10 but should work fine on Vista, 7, 8 and 8.1.
You can create a custom page in NSIS to ask for (and verify) specific information:
!include MUI2.nsh
Page Custom MyVerifyPageCreate MyVerifyPageLeave
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English
!include nsDialogs.nsh
!include LogicLib.nsh
!define MIN_AGE 21
Var Age
Function MyVerifyPageCreate
!ifmacrodef MUI_HEADER_TEXT
!insertmacro MUI_HEADER_TEXT "Blah" "Blah blah blah"
!endif
nsDialogs::Create 1018
Pop $0
${NSD_CreateLabel} 10u 21u 100% 12u "Blah blah blah age ${MIN_AGE} blah blah"
Pop $0
${NSD_CreateNumber} 10u 35u 30u 12u "$Age"
Pop $1
nsDialogs::Show
FunctionEnd
Function MyVerifyPageLeave
${NSD_GetText} $1 $Age
${If} $Age < ${MIN_AGE}
MessageBox MB_IconStop "You must be at least ${MIN_AGE} to install $(^Name)!"
Abort
${EndIf}
FunctionEnd
Or if the user needs to enter a date:
!include MUI2.nsh
Page Custom MyVerifyPageCreate MyVerifyPageLeave
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE English
!include nsDialogs.nsh
!include LogicLib.nsh
!define /IfNDef GDT_VALID 0
!define /IfNDef DTS_LONGDATEFORMAT 4
!define /IfNDef /math DTM_GETSYSTEMTIME 0x1000 + 1
!define MIN_AGE 18
Function MyVerifyPageCreate
!ifmacrodef MUI_HEADER_TEXT
!insertmacro MUI_HEADER_TEXT "Blah" "Blah blah blah"
!endif
System::Call 'COMCTL32::InitCommonControlsEx(*l0x10000000008)'
nsDialogs::Create 1018
Pop $0
${NSD_CreateLabel} 10u 21u -20u 25u "Blah blah blah age ${MIN_AGE} blah blah$\r$\n$\r$\nEnter your birthday:"
Pop $0
nsDialogs::CreateControl SysDateTimePick32 ${DEFAULT_STYLES}|${WS_TABSTOP}|${DTS_LONGDATEFORMAT} ${__NSD_Text_EXSTYLE} 10u 50u 200u 12u "" ; Probably only works on Win98 and higher
Pop $1
nsDialogs::Show
FunctionEnd
Function MyVerifyPageLeave
; NOTE: Does not deal with leap years etc!
System::Call 'USER32::SendMessage(p$1, i${DTM_GETSYSTEMTIME}, p0, #r2)i.r0'
${If} $0 = ${GDT_VALID}
System::Call 'KERNEL32::SystemTimeToFileTime(pr2,*l.r2)'
System::Call 'KERNEL32::GetSystemTimeAsFileTime(*l.r3)' ; Current time (UTC)
System::Call 'KERNEL32::FileTimeToLocalFileTime(*lr3,*l.r3)'
System::Int64Op ${MIN_AGE} * 315360000000000 ; 1 year (KB 188768)
System::Int64Op $2 +
Pop $2
${IfThen} $2 L< $3 ${|} StrCpy $0 "OK" ${|}
${EndIf}
${If} $0 != "OK"
MessageBox MB_IconStop "You must be at least ${MIN_AGE} to install $(^Name)!"
Abort
${EndIf}
FunctionEnd