Arduino When keep pressing button a continuous Letter is show - arduino

Question

First of all sorry for my weak English
I have Arduino Leonardo
and I have a push-button ok?
When I click the button the letter 'W' is printed to the notepad
ok?
I Want when I keep holding the button the 'w' Letter is printed
why? like in games when I keep holding on 'W' letter the player will move, then when I release my finger the player will stop.
Please please please I need your help because I'm a beginner
This is my code
#include "Keyboard.h"
const int buttonPin = 4; // input pin for pushbutton
int previousButtonState = HIGH; // for checking the state of a pushButton
void setup() {
// make the pushButton pin an input:
pinMode(buttonPin, INPUT);
// initialize control over the keyboard:
Keyboard.begin();
}
void loop() {
// read the pushbutton:
int buttonState = digitalRead(buttonPin);
// if the button state has changed,
if ((buttonState != previousButtonState)
// and it's currently pressed:
&& (buttonState == HIGH)) {
// type out a message
Keyboard.print("W");
}
// save the current button state for comparison next time:
previousButtonState = buttonState;
}

Answer 1

First, the reason why your code only acts as if the button was pressed once are the following lines
// if the button state has changed,
if ((buttonState != previousButtonState)
// and it's currently pressed:
&& (buttonState == HIGH)) {
so, this will only be true once after the button gets pressed. If you remove the previous state check and only check if the button is currently high it will trigger a press every time your programm loops. This will have side effects though, like a short press will likely trigger multiple times.
Fortunately, there is another function provided by the keyboard library to solve this issue: Keyboard.press()
When called, Keyboard.press() functions as if a key were pressed and held on your keyboard. Useful when using modifier keys. To end the key press, use Keyboard.release() or Keyboard.releaseAll().
https://www.arduino.cc/reference/en/language/functions/usb/keyboard/keyboardpress/
So, if you modify your code like this:
void loop() {
// read the pushbutton:
int buttonState = digitalRead(buttonPin);
// if the button state has changed,
if (buttonState != previousButtonState){
if( buttonState == HIGH ) {
Keyboard.press('w');
}else{
Keyboard.release('w');
}
}
// save the current button state for comparison next time:
previousButtonState = buttonState;
}
it will act exactly as if the keyboard button keeps beeing pressed.
Please note that currently the script will likely act as if the button is pressed a few times per press because of bouncing. You could fix this issue by adding a small delay after the button press and release part. This will give the button time to settle to the new state. Read more about bouncing here: https://www.allaboutcircuits.com/textbook/digital/chpt-4/contact-bounce/