Defining a subclass with parameters in Isabelle - isabelle

Question

The documentation on typeclasses in Isabelle (section 3.5) explains how to define additional subclass relations "after the fact", by giving proofs of the missing axioms. Is there a way to do this when the subclass adds parameters in addition to axioms?
For instance, suppose I have the following classes:
class setoid =
fixes eq :: "'a ⇒ 'a ⇒ bool" (infix "≈" 50)
assumes eq_refl : "∀x. x ≈ x"
and eq_symm : "∀x y. x ≈ y ⟶ y ≈ x"
and eq_trans : "∀x y z. x ≈ y ⟶ y ≈ z ⟶ x ≈ z"
class preorder =
fixes le :: "'a ⇒ 'a ⇒ bool" (infix "≲" 50)
assumes le_refl : "∀x. x ≲ x"
and le_trans : "∀x y z. x ≲ y ⟶ y ≲ z ⟶ x ≲ z"
Every preorder should be a setoid when we symmetrize its inequality:
definition (in preorder) peq :: "'a ⇒ 'a ⇒ bool"
where "peq x y ≡ (x ≲ y) ∧ (y ≲ x)"
However, the following fails:
subclass (in preorder) setoid
with the error exception TYPE raised: Class preorder lacks parameter(s) "setoid_class.eq" of setoid. But I can't figure out a syntax to tell Isabelle that this missing parameter should be the relation peq that I defined.
I can do it if I drop down to locales instead of typeclasses (proofs omitted for brevity):
interpretation peq_class : setoid peq
proof
show "∀x. peq x x" sorry
show "∀x y. peq x y ⟶ peq y x" sorry
show "∀x y z. peq x y ⟶ peq y z ⟶ peq x z" sorry
qed
But this doesn't allow me to use a preorder as a setoid, i.e. the interpretation doesn't act like a subclass or an instantiation. What I want is to be able to instantiate a type as a preorder and then automatically be able to use definitions and theorems about setoids on that type, by way of the symmetrization of its inequality. How can I achieve this?

Answer 1

This is a restriction of the way type classes are implemented in Isabelle. I'm not sure if the following workaround is as short as it could be, but it works:
class eq =
fixes eq :: "'a ⇒ 'a ⇒ bool" (infix "≈" 50)
class setoid = eq +
assumes eq_refl : "∀x. x ≈ x"
and eq_symm : "∀x y. x ≈ y ⟶ y ≈ x"
and eq_trans : "∀x y z. x ≈ y ⟶ y ≈ z ⟶ x ≈ z"
class preorder =
fixes le :: "'a ⇒ 'a ⇒ bool" (infix "≲" 50)
assumes le_refl : "∀x. x ≲ x"
and le_trans : "∀x y z. x ≲ y ⟶ y ≲ z ⟶ x ≲ z"
class preorder_setoid = preorder + eq +
assumes eq_def: "x ≈ y ⟷ (x ≲ y) ∧ (y ≲ x)"
subclass (in preorder_setoid) setoid
apply standard
unfolding eq_def
using le_refl le_trans by auto
The downside is that you still can't make any instance of preorder a setoid automatically, but you have to do it manually. For each preorder instance, you can add a preorder_setoid instance. All of these will look identical; they have to define eq according to eq_def. The proof is then automatic.
Update As pointed out in the comments, the eq constant will always be interpreted in the context of the eq class; i.e., nothing interesting can be proved without further type annotations. It is possible to tell type inference to do better:
setup {*
Sign.add_const_constraint (#{const_name "eq"}, SOME #{typ "'a::setoid ⇒ 'a ⇒ bool"})
*}